refactor: Convert itinerary legs to segments for easier rendering

lib/dotcom/trip_plan/input_form.ex

@@ -49,6 +49,7 @@ defmodule Dotcom.TripPlan.InputForm do
       date: PlanParams.to_date_param(datetime),
       time: PlanParams.to_time_param(datetime),
       transportModes: __MODULE__.Modes.selected_mode_keys(modes) |> PlanParams.to_modes_param(),
+      numItineraries: 40,
       wheelchair: wheelchair
     }
     |> PlanParams.new()

lib/dotcom_web/components/trip_planner/itinerary_detail.ex

@@ -10,7 +10,7 @@ defmodule DotcomWeb.Components.TripPlanner.ItineraryDetail do
   import DotcomWeb.Components.TripPlanner.TransitLeg, only: [transit_leg: 1]
   import DotcomWeb.Components.TripPlanner.WalkingLeg, only: [walking_leg: 1]
 
-  alias Dotcom.TripPlan.{PersonalDetail, TransitDetail}
+  alias DotcomWeb.Components.TripPlanner.LegToSegmentHelper
 
   def itinerary_detail(
         %{
@@ -77,27 +77,44 @@ defmodule DotcomWeb.Components.TripPlanner.ItineraryDetail do
 
   defp specific_itinerary_detail(assigns) do
     assigns =
-      assigns
-      |> assign(:start_place, List.first(assigns.itinerary.legs).from)
-      |> assign(:start_time, List.first(assigns.itinerary.legs).start)
-      |> assign(:end_place, List.last(assigns.itinerary.legs).to)
-      |> assign(:end_time, List.last(assigns.itinerary.legs).stop)
+      assign(
+        assigns,
+        :segments,
+        LegToSegmentHelper.legs_to_segments(assigns.itinerary.legs)
+      )
 
     ~H"""
     <div class="mt-4">
-      <.place place={@start_place} time={@start_time} />
-      <div
-        :for={leg <- @itinerary.legs}
-        class={"#{if(match?(%TransitDetail{}, leg.mode), do: "bg-gray-bordered-background")}"}
-      >
-        <%= if match?(%PersonalDetail{}, leg.mode) do %>
-          <.walking_leg leg={leg} />
-        <% else %>
-          <.transit_leg leg={leg} />
-        <% end %>
+      <div :for={segment <- @segments}>
+        <.segment segment={segment} />
       </div>
-      <.place place={@end_place} time={@end_time} />
     </div>
     """
   end
+
+  defp segment(%{segment: {:location_segment, %{time: time, place: place}}} = assigns) do
+    assigns =
+      assigns
+      |> assign(:time, time)
+      |> assign(:place, place)
+
+    ~H"""
+    <.place place={@place} time={@time} />
+    """
+  end
+
+  defp segment(%{segment: {:walking_segment, leg}} = assigns) do
+    assigns = assign(assigns, :leg, leg)
+
+    ~H"""
+    <.walking_leg leg={@leg} />
+    """
+  end
+
+  defp segment(%{segment: {:transit_segment, leg}} = assigns) do
+    assigns = assign(assigns, :leg, leg)
+    ~H"""
+    <.transit_leg leg={@leg} />
+    """
+  end
 end

lib/dotcom_web/components/trip_planner/leg_to_segment_helper.ex

@@ -0,0 +1,37 @@
+defmodule DotcomWeb.Components.TripPlanner.LegToSegmentHelper do
+  alias Dotcom.TripPlan.{PersonalDetail, TransitDetail}
+
+  def legs_to_segments(legs) do
+    legs
+    |> raw_convert_to_segments()
+    |> prepend_start_location()
+    |> append_end_location()
+  end
+
+  defp raw_convert_to_segments(legs) do
+    Enum.map(legs, &to_segment/1)
+  end
+
+  defp to_segment(%{mode: %PersonalDetail{}} = leg) do
+    {:walking_segment, leg}
+  end
+
+  defp to_segment(%{mode: %TransitDetail{}} = leg) do
+    {:transit_segment, leg}
+  end
+
+  defp prepend_start_location([{_, leg} | _] = segments) do
+    [
+      {:location_segment, %{time: leg.start, place: leg.from}}
+      | segments
+    ]
+  end
+
+  defp append_end_location([{_, leg} = last_leg]) do
+    [last_leg, {:location_segment, %{time: leg.stop, place: leg.to}}]
+  end
+
+  defp append_end_location([first_leg | rest_of_legs]) do
+    [first_leg | append_end_location(rest_of_legs)]
+  end
+end

lib/dotcom_web/components/trip_planner/transit_leg.ex

@@ -23,7 +23,7 @@ defmodule DotcomWeb.Components.TripPlanner.TransitLeg do
 
   def transit_leg(assigns) do
     ~H"""
-    <div>
+    <div class="bg-gray-bordered-background">
       <.place
         place={@leg.from}
         time={@leg.start}

test/dotcom_web/components/trip_planner/leg_to_segment_helper_test.exs

@@ -0,0 +1,23 @@
+defmodule DotcomWeb.Components.TripPlanner.LegToSegmentHelperTest do
+  @moduledoc false
+
+  use ExUnit.Case, async: true
+
+  alias Dotcom.TripPlan.{Leg, PersonalDetail, TransitDetail}
+  alias DotcomWeb.Components.TripPlanner.LegToSegmentHelper
+
+  test "works for a typical walking-transit-walking itinerary and puts a location on either end" do
+    assert [
+             {:location_segment, _},
+             {:walking_segment, _},
+             {:transit_segment, _},
+             {:walking_segment, _},
+             {:location_segment, _}
+           ] =
+             LegToSegmentHelper.legs_to_segments([
+               %Leg{mode: %PersonalDetail{}},
+               %Leg{mode: %TransitDetail{}},
+               %Leg{mode: %PersonalDetail{}}
+             ])
+  end
+end