WIP: adds support for expecting on global functions and namespace functions

[georgejecook]

Adds support for expecting on global functions and namespaced functions.
DOCS

Mocking global and namespaced functions

Mocking and stubbing of global functions works the same as for class methods. Please note, the functions must be in scope - you cannot mock a global function call inside of a node. So if your call crosses an observer, or callfunc bridge, it will not work. This is by design, and there are no plans to provide intra-node global or namespace mocking, at this point.

To enable this feature, set the isGlobalMethodMockingEnabled rooibos config parameter to true. DO NOT enable this on your ide's bsconfig.json, as it will negatively impact performance and may cause other issues. This setting is not compatible with watch mode, at this moment.

Configuration

In addition to the isGlobalMethodMockingEnabled, you use the following config flags:

• isGlobalMethodMockingEfficientMode - default to true, when set causes rooibos to modify only those functions that were mocked or stubbed
• globalMethodMockingExcludedFiles - files that rooibos will not modify, when adding global mocking or stubbing support.

Known limitations:

You must include default values in your expect calls, even if your invoking code does not use them

• if you mock or stub a global or namespaced method, you will have to expect default parameters in your expectCalled invocation, as rooibos will receive the default values.

e.g.

namespace utils
  function getModel(name as string, asJson = false as boolean)
  end function
end namespace

'in the code
function getBeatlesModel()
  utils.getModel("Ringo")
end function

'in the unit test
@describe("getBeatlesModel")
@it("gets ringo")
function _()
  'This will fail, because rooibos will receive the asJson param with the default value
  m.expectCalled(utils.getModel("ringo"))

  'therefore we need to do this
  m.expectCalled(utils.getModel("ringo", false))
end function

Note - this will be addressed shortly; pr's are welcome in the interim.

There might be some bugs, or unknown issues

Mocking, of global and namespaced functions is supported; but is a relatively new feature. It is possible that there are some scenarios that are not supported. Please raise issues in the rooibos slack channel, if you spot any anomalies.

EXAMPLE

Given Global.bs, with contents

function globalSayHello(firstName = "" as string, lastName = "" as string)
  return firstName + ", " + lastName
end function

namespace utils
  function sayHello(firstName = "" as string, lastName = "" as string)
    return firstName + ", " + lastName
  end function
end namespace

Once can now write tests like this:

    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    @describe("global functions")
    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

    @it("uses default implementation on global functions")
    function _()
      m.assertEqual(utils.sayHello("John", "Lennon"), "John, Lennon")
    end function

    @it("uses default implementation on namespaced functions")
    function _()
      m.assertEqual(globalSayHello("John", "Lennon"), "John, Lennon")
    end function

    @it("supports mocks on global functions")
    function _()
      m.expectCalled(globalSayHello("John", "Lennon"), "john")

      m.assertEqual(globalSayHello("John", "Lennon"), "john")
    end function

    @it("supports mocks on namespaced functions")
    function _()
      m.expectCalled(utils.sayHello("Paul", "McCartney"), "paul")

      m.assertEqual(utils.sayHello("Paul", "McCartney"), "paul")
    end function

    @it("reports uncalled mocks on global functions")
    function _()
      m.expectCalled(globalSayHello("John", "Lennon"), "john")

      m.assertRunningTestIsFailed()
    end function

    @it("reports uncalled mocks on namespaced functions")
    function _()
      m.expectCalled(utils.sayHello("Paul", "McCartney"), "paul")

      m.assertRunningTestIsFailed()
    end function

    @it("resets to default implementation on global functions")
    function _()
      m.assertEqual(utils.sayHello("John", "Lennon"), "John, Lennon")
    end function

    @it("resets to default implementation on namespaced functions")
    function _()
      m.assertEqual(globalSayHello("John", "Lennon"), "John, Lennon")
    end function

    @it("supports overloaded mocks on global functions")
    function _()
      m.expectCalled(globalSayHello("John", "Lennon"), "john")
      m.expectCalled(globalSayHello("John", "Lennon"), "john2")

      m.assertEqual(globalSayHello("John", "Lennon"), "john")
      m.assertEqual(globalSayHello("John", "Lennon"), "john2")
    end function

    @it("supports overloaded mocks on namespaced functions")
    function _()
      m.expectCalled(utils.sayHello("Paul", "McCartney"), "paul1")
      m.expectCalled(utils.sayHello("Paul", "McCartney"), "paul2")

      m.assertEqual(utils.sayHello("Paul", "McCartney"), "paul1")
      m.assertEqual(utils.sayHello("Paul", "McCartney"), "paul2")
    end function

[TwitchBronBron]

Why do you hate proper indentation? :P

[georgejecook]

lol. I honestly find if I do anything else, it won't pass the test. Always been too busy to sort it out.