dev-util/find-work-repology: new package, add 0.1.0

Signed-off-by: Anna (cybertailor) Vyalkova <[email protected]>

dev-util/find-work-repology/Manifest

@@ -0,0 +1 @@
+DIST find_work_repology-0.1.0.tar.gz 6783 BLAKE2B 9b8d94e16e3d1affd4945e8d62cc8e9b9225beeb14819e3f7dec08ba55b3e712fc8275ddb86abf2ba8846d256f1785e5fbe8f5fcbee7ea978078767c26d34f02 SHA512 755419fbdd31ace4e6d24fd7102c1f429482a950d9dd205dcf8b6c1db075e310d13a0eab7a4f4d84d2d8355cc0be6259898da199036fcc59492db67789593b8a

dev-util/find-work-repology/find-work-repology-0.1.0.ebuild

@@ -0,0 +1,43 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..12} )
+DISTUTILS_USE_PEP517=flit
+inherit distutils-r1 pypi
+
+DESCRIPTION="Personal advice utility for Gentoo package maintainers: Repology plugin"
+HOMEPAGE="
+	https://find-work.sysrq.in/
+	https://pypi.org/project/find-work-repology/
+"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<app-portage/gentoopm-2[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/click-aliases[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2[${PYTHON_USEDEP}]
+	<dev-python/pydantic-3[${PYTHON_USEDEP}]
+	>=dev-python/repology-client-0.0.2[${PYTHON_USEDEP}]
+	<dev-python/repology-client-2[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+	>=dev-util/find-work-0.90[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-import-check[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace find_work
+	epytest "${S}"
+}

dev-util/find-work-repology/metadata.xml

@@ -12,6 +12,5 @@
 		</maintainer>
 		<remote-id type="pypi">find-work-repology</remote-id>
 		<bugs-to>https://bugs.sysrq.in/enter_bug.cgi?product=Software&amp;component=find-work</bugs-to>
-		<changelog>https://find-work.sysrq.in/release-notes.html</changelog>
 	</upstream>
 </pkgmetadata>