media-sound/TauonMusicBox: add 7.8.3

Signed-off-by: David Roman <[email protected]>

media-sound/TauonMusicBox/Manifest

@@ -1 +1,2 @@
 DIST TauonMusicBox-7.8.0.tar.gz 1080654 BLAKE2B 6c671efc10f0e7340bb2db0ebcc59f25784a665a9a2e85ab5132a10362d9d0f7041affedc763ed5acde19c529c742e127eb1493578f9f79ca7f3b1dfd4439784 SHA512 0896e185314037e23d76776ce96b227ede8a96651958df7ca0acc0d37c431169aeb72395116d8887d37c1360c15f436f7488c751866e60fa5ba3a5082b9acef8
+DIST TauonMusicBox-7.8.3.tar.gz 1085686 BLAKE2B 92014544bc45c92ca8170ae88c56eb2a767b0dff2dcd1086cb73d22a4287b6a82be7b3134a41329940ccc6080377d82b71c2d9ef891975d62756068c8a97f867 SHA512 f1679326a49c1d341ea773b5f402fa4ad00ac2c79549fc04b2959bdf2dfad045e6e88add5b9075e660016a4d94d15e43e5d5c93e6f413e727d30f5aaa8fbdc1d

media-sound/TauonMusicBox/TauonMusicBox-7.8.3.ebuild

@@ -0,0 +1,126 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit cmake desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+S="${WORKDIR}/Tauon-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/PySDL2[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl2-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+	# Workaround. If PATCHES is used it would be applied to times and fail
+	eapply "${FILESDIR}/${PN}-7.8.0-phazor-fix.patch"
+
+	distutils-r1_src_prepare
+	cmake_src_prepare
+}
+
+src_configure() {
+	distutils-r1_src_configure
+	cmake_src_configure
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	cmake_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+src_test() {
+	distutils-r1_src_test
+	cmake_src_test
+}
+
+python_install() {
+	newbin tauon.py tauon
+	dolib.so  "${WORKDIR}/Tauon-${PV}_build/libphazor.so"
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	insinto "/usr/share/${PN}"
+	doins -r assets theme templates
+	doins input.txt
+
+	sed -i 's/\/opt\/tauon-music-box\/tauonmb.sh/tauon/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+
+	xdg_pkg_postinst
+}