Parallel cyclic reduction

CMakeLists.txt

@@ -185,6 +185,8 @@ set(BOUT_SOURCES
   ./src/invert/laplace/impls/multigrid/multigrid_solver.cxx
   ./src/invert/laplace/impls/naulin/naulin_laplace.cxx
   ./src/invert/laplace/impls/naulin/naulin_laplace.hxx
+  ./src/invert/laplace/impls/pcr/pcr.cxx
+  ./src/invert/laplace/impls/pcr/pcr.hxx
   ./src/invert/laplace/impls/pdd/pdd.cxx
   ./src/invert/laplace/impls/pdd/pdd.hxx
   ./src/invert/laplace/impls/petsc/petsc_laplace.cxx
@@ -343,6 +345,10 @@ target_include_directories(bout++ PUBLIC
 target_compile_features(bout++ PUBLIC cxx_std_14)
 set_target_properties(bout++ PROPERTIES CXX_EXTENSIONS OFF)
 
+# Various sanitizers, including coverage and address sanitizer
+include(cmake/Sanitizers.cmake)
+enable_sanitizers(bout++)
+
 ##################################################
 # Components of the version number
 # Pre-release identifier (BOUT_VERSION_TAG) set above

cmake/Sanitizers.cmake

@@ -0,0 +1,109 @@
+# Adapted from
+# https://github.com/lefticus/cpp_starter_project/blob/master/cmake/Sanitizers.cmake
+# Public domain
+
+function(enable_sanitizers target_name)
+
+  if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+    option(ENABLE_COVERAGE "Enable coverage reporting for gcc/clang" FALSE)
+    message(STATUS "Enable coverage: ${ENABLE_COVERAGE}")
+
+    if(ENABLE_COVERAGE)
+      target_compile_options(${target_name} PUBLIC --coverage -O0 -g)
+      target_link_libraries(${target_name} PUBLIC --coverage)
+
+      find_program(fastcov_FOUND fastcov)
+      message(STATUS "Looking for fastcov: ${fastcov_FOUND}")
+      find_program(genhtml_FOUND genhtml)
+      message(STATUS "Looking for genhtml: ${fastcov_FOUND}")
+
+      if (fastcov_FOUND AND genhtml_FOUND)
+        set(COVERAGE_NAME coverage CACHE STRING "Name of coverage output file")
+        set(COVERAGE_FILE "${COVERAGE_NAME}.info")
+        set(COVERAGE_MSG "Open file://${PROJECT_SOURCE_DIR}/${COVERAGE_NAME}/index.html in your browser to view coverage HTML output")
+
+        add_custom_target(code-coverage-capture
+          COMMAND
+            fastcov --include "${CMAKE_CURRENT_SOURCE_DIR}/src" "${CMAKE_CURRENT_SOURCE_DIR}/include"
+            --exclude "${CMAKE_CURRENT_SOURCE_DIR}/externalpackages"
+            --lcov --process-gcno
+            --output "${COVERAGE_FILE}"
+          COMMAND
+            genhtml --output-directory "${COVERAGE_NAME}" --demangle-cpp --legend --show-details "${COVERAGE_FILE}"
+          COMMAND
+            "${CMAKE_COMMAND}" -E echo ${COVERAGE_MSG}
+          WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+          COMMENT "Capturing coverage information"
+          BYPRODUCTS
+            "${COVERAGE_FILE}"
+            "${COVERAGE_NAME}/index.html"
+          )
+
+        add_custom_target(code-coverage-clean
+          COMMAND
+          fastcov --zerocounters
+          COMMENT "Cleaning coverage information"
+          )
+      else()
+        message(STATUS "Coverage enabled, but coverage-capture not available. Please install fastcov and lcov")
+      endif()
+
+    endif()
+
+    set(SANITIZERS "")
+
+    option(ENABLE_SANITIZER_ADDRESS "Enable address sanitizer" FALSE)
+    if(ENABLE_SANITIZER_ADDRESS)
+      list(APPEND SANITIZERS "address")
+    endif()
+
+    option(ENABLE_SANITIZER_LEAK "Enable leak sanitizer" FALSE)
+    if(ENABLE_SANITIZER_LEAK)
+      list(APPEND SANITIZERS "leak")
+    endif()
+
+    option(ENABLE_SANITIZER_UNDEFINED_BEHAVIOR "Enable undefined behavior sanitizer" FALSE)
+    if(ENABLE_SANITIZER_UNDEFINED_BEHAVIOR)
+      list(APPEND SANITIZERS "undefined")
+    endif()
+
+    option(ENABLE_SANITIZER_THREAD "Enable thread sanitizer" FALSE)
+    if(ENABLE_SANITIZER_THREAD)
+      if("address" IN_LIST SANITIZERS OR "leak" IN_LIST SANITIZERS)
+        message(WARNING "Thread sanitizer does not work with Address and Leak sanitizer enabled")
+      else()
+        list(APPEND SANITIZERS "thread")
+      endif()
+    endif()
+
+    option(ENABLE_SANITIZER_MEMORY "Enable memory sanitizer" FALSE)
+    if(ENABLE_SANITIZER_MEMORY AND CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+      if("address" IN_LIST SANITIZERS
+         OR "thread" IN_LIST SANITIZERS
+         OR "leak" IN_LIST SANITIZERS)
+        message(WARNING "Memory sanitizer does not work with Address, Thread and Leak sanitizer enabled")
+      else()
+        list(APPEND SANITIZERS "memory")
+      endif()
+    endif()
+
+    list(
+      JOIN
+      SANITIZERS
+      ","
+      LIST_OF_SANITIZERS)
+
+  endif()
+
+  if(LIST_OF_SANITIZERS)
+    if(NOT
+       "${LIST_OF_SANITIZERS}"
+       STREQUAL
+       "")
+      message(STATUS "Sanitizers enabled: ${LIST_OF_SANITIZERS}")
+      target_compile_options(${target_name} PUBLIC -fsanitize=${LIST_OF_SANITIZERS} -fno-omit-frame-pointer)
+      target_link_options(${target_name} PUBLIC -fsanitize=${LIST_OF_SANITIZERS})
+    endif()
+  endif()
+
+endfunction()

include/invert_laplace.hxx

@@ -61,6 +61,7 @@ constexpr auto LAPLACE_CYCLIC = "cyclic";
 constexpr auto LAPLACE_MULTIGRID = "multigrid";
 constexpr auto LAPLACE_NAULIN = "naulin";
 constexpr auto LAPLACE_IPT = "ipt";
+constexpr auto LAPLACE_PCR = "pcr";
 
 // Inversion flags for each boundary
 /// Zero-gradient for DC (constant in Z) component. Default is zero value

src/invert/laplace/impls/makefile

@@ -1,6 +1,6 @@
 
 BOUT_TOP = ../../../..
 
-DIRS            = serial_tri serial_band pdd spt petsc cyclic multigrid naulin petsc3damg iterative_parallel_tri
+DIRS            = serial_tri serial_band pdd spt petsc cyclic multigrid naulin petsc3damg iterative_parallel_tri pcr
 
 include $(BOUT_TOP)/make.config

src/invert/laplace/impls/pcr/makefile

@@ -0,0 +1,8 @@
+
+BOUT_TOP = ../../../../..
+
+SOURCEC         = pcr.cxx
+SOURCEH         = pcr.hxx
+TARGET          = lib
+
+include $(BOUT_TOP)/make.config