Method for getting an IEDs dial code

[The-Pink-Panther]

I am currently making a mission in which I want an AI IED spotter to be able to detonate a cellphone IED after seing a player. I am currently using this script to spawn the IED:
iedOne = [player, [2576.687,8859.097,0], 0, "IEDLandBig_Remote_Mag", "Cellphone", [player, this], placeHolder] call ace_explosives_fnc_placeExplosive;
This works as intended and adds the IED to the speed dial menu, the problem comes when trying to detonate the device. I'm trying to use fnc_dialPhone.sqf but this requires the dial code, fnc_getSpeedDialExplosive.sqf returns the IED from the dial code, a function that did the opposite and returned the dial code for a specified IED would be great.

[Whigital]

Just scanned through the code, and Cellphone connected IEDs are added into an array called ace_explosives_CellphoneIEDs, which is also broadcasted to all clients.

This array contains the ied, code and trigger delay:

ACE3/addons/explosives/functions/fnc_addCellphoneIED.sqf

Lines 47 to 49 in af66a98

	private _count = GVAR(CellphoneIEDs) pushBack [_explosive, _code, getNumber (configFile >> "CfgMagazines" >> _magazineClass >> "ACE_Triggers" >> "Cellphone" >> "FuseTime")];
	_count = _count + 1;
	publicVariable QGVAR(CellphoneIEDs);

So if you have a reference to the IED object, it should just be a simple matter of extracting it from the array:

params [["_ied", objNull]];

if (isNull _ied) exitWith {
    diag_log "Null object passed to get IED code ....";
    -1
};

private _iedIdx = (ace_explosives_CellphoneIEDs findIf {(_x # 0) == _ied});

if (_iedIdx == -1) exitWith {
    diag_log "IED not found in Cellphone array ....";
    -1
};

private _iedData = (ace_explosives_CellphoneIEDs # _iedIdx);

(_iedData # 1)

[The-Pink-Panther]

Checked and it works, thanks.