build.gradle

plugins {
	id 'fabric-loom' version '1.5-SNAPSHOT'
	id 'maven-publish'
}

loom.runs.configureEach {
	ideConfigGenerated project.rootProject == project
}

base {
	archivesName = project.archives_base_name
}

allprojects {
	apply plugin: "fabric-loom"
	version = project.mod_version
	group = project.maven_group

	repositories {
		// Add repositories to retrieve artifacts from in here.
		// You should only use this when depending on other mods because
		// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
		// See https://docs.gradle.org/current/userguide/declaring_repositories.html
		// for more information about repositories.
	}

	dependencies {
		// To change the versions see the gradle.properties file
		minecraft "com.mojang:minecraft:${project.minecraft_version}"
		// mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
		mappings loom.officialMojangMappings()
		modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

		// Fabric API. This is technically optional, but you probably want it anyway.
		modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
		compileOnly "com.google.code.findbugs:jsr305:3.0.2"
		implementation "net.neoforged:bus:${project.neoforge_bus_version}"
		
		// Uncomment the following line to enable the deprecated Fabric API modules. 
		// These are included in the Fabric API production distribution and allow you to update your mod to the latest modules at a later more convenient time.

		// modImplementation "net.fabricmc.fabric-api:fabric-api-deprecated:${project.fabric_version}"
	}

	loom {
		splitEnvironmentSourceSets()
	}

	processResources {
		inputs.property "version", project.version

		filesMatching("fabric.mod.json") {
			filter {
				return it.replace("\${version}", project.version)
			}
		}
	}

	tasks.withType(JavaCompile).configureEach {
		it.options.release = 17
	}

	java {
		// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
		// if it is present.
		// If you remove this line, sources will not be generated.
		withSourcesJar()

		sourceCompatibility = JavaVersion.VERSION_17
		targetCompatibility = JavaVersion.VERSION_17
	}

	jar {
		from("LICENSE") {
			rename { "${it}_${project.base.archivesName.get()}"}
		}
	}
}

allprojects.each { p ->
	loom.mods.register(p.name) {
		sourceSet p.sourceSets.main
		sourceSet p.sourceSets.client
	}
}

dependencies {
	afterEvaluate {
		subprojects.each {
			api project(path: "${it.path}", configuration: "namedElements")
			clientImplementation project("${it.path}:").sourceSets.client.output
		}
	}
	include "net.neoforged:bus:${project.neoforge_bus_version}"
	include "org.apache.maven:maven-artifact:${project.apache_maven_artifact_version}"
}

subprojects {
	base {
		archivesName = project.name
	}
}

remapJar {
	afterEvaluate {
		subprojects.each {
			if (it.name != "shearapi-compile-fml") {
				nestedJars.from project("${it.path}").tasks.getByName("remapJar")
			}
		}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}