forked from protesilaos/tmr
-
Notifications
You must be signed in to change notification settings - Fork 0
/
tmr-tabulated.el
157 lines (136 loc) · 6.17 KB
/
tmr-tabulated.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
;;; tmr-tabulated.el --- Display TMR timers in a tabulated list -*- lexical-binding: t -*-
;; Copyright (C) 2020-2024 Free Software Foundation, Inc.
;; Author: Protesilaos Stavrou <[email protected]>,
;; Damien Cassou <[email protected]>,
;; Daniel Mendler <[email protected]>
;; Maintainer: Protesilaos Stavrou <[email protected]>
;; URL: https://github.com/protesilaos/tmr
;; This file is NOT part of GNU Emacs.
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; Call `M-x tmr-tabulated-view' to display all tmr timers in a grid,
;; one by line with sortable columns. Columns show the creation date,
;; the end date, a check mark if the timer is finished and the timer's
;; optional description.
;;
;; Please read the manual for all the technicalities. Either evaluate
;; (info "(tmr) Top") or visit <https://protesilaos.com/emacs/tmr>.
;;; Code:
(require 'tmr)
;;;###autoload
(defun tmr-tabulated-view ()
"Open a tabulated list buffer listing tmr timers."
(interactive)
(switch-to-buffer (get-buffer-create "*tmr-tabulated-view*"))
(tmr-tabulated-mode))
(defalias 'tmr-list-timers 'tmr-tabulated-view
"Alias for `tmr-tabulated-view' command.")
(defun tmr-tabulated--set-entries ()
"Set the value of `tabulated-list-entries' with timers."
(setq-local tabulated-list-entries
(mapcar #'tmr-tabulated--timer-to-entry tmr--timers)))
(defun tmr-tabulated--timer-to-entry (timer)
"Convert TIMER into an entry suitable for `tabulated-list-entries'."
(list timer
(vector (tmr--format-creation-date timer)
(tmr--format-end-date timer)
(tmr--format-remaining timer)
(if (tmr--timer-acknowledgep timer) tmr-finished-indicator "")
(or (tmr--timer-description timer) ""))))
(defvar-keymap tmr-tabulated-mode-map
:doc "Keybindings for `tmr-tabulated-mode-map'."
"k" #'tmr-remove
"r" #'tmr-remove
"R" #'tmr-remove-finished
"+" #'tmr
"t" #'tmr
"*" #'tmr-with-details
"T" #'tmr-with-details
"c" #'tmr-clone
"a" #'tmr-toggle-acknowledge
"e" #'tmr-edit-description
"s" #'tmr-reschedule)
(defvar-local tmr-tabulated--refresh-timer nil
"Timer used to refresh tabulated view.")
(defun tmr-tabulated--window-hook ()
"Setup timer to refresh tabulated view."
(if (get-buffer-window)
(unless tmr-tabulated--refresh-timer
(let* ((timer nil)
(buf (current-buffer))
(refresh
(lambda ()
(if (buffer-live-p buf)
(with-current-buffer buf
(if-let (win (get-buffer-window))
(with-selected-window win
(let ((end (eobp)))
;; Optimized refreshing
(dolist (entry tabulated-list-entries)
(setf (aref (cadr entry) 2) (tmr--format-remaining (car entry))))
(tabulated-list-print t)
(when end (goto-char (point-max))))
;; HACK: For some reason the hl-line highlighting gets lost here
(when (and (bound-and-true-p global-hl-line-mode)
(fboundp 'global-hl-line-highlight))
(global-hl-line-highlight))
(when (and (bound-and-true-p hl-line-mode)
(fboundp 'hl-line-highlight))
(hl-line-highlight)))
(cancel-timer timer)
(setq tmr-tabulated--refresh-timer nil)))
(cancel-timer timer)))))
(setq timer (run-at-time 1 1 refresh)
tmr-tabulated--refresh-timer timer)))
(when tmr-tabulated--refresh-timer
(cancel-timer tmr-tabulated--refresh-timer)
(setq tmr-tabulated--refresh-timer nil))))
(defun tmr-tabulated--compare-remaining (a b)
"Compare remaining time of timers A and B."
(time-less-p (tmr--timer-end-date (car a))
(tmr--timer-end-date (car b))))
(define-derived-mode tmr-tabulated-mode tabulated-list-mode "TMR"
"Major mode to display tmr timers."
(setq-local tabulated-list-format
[("Start" 10 t)
("End" 10 t)
("Remaining" 10 tmr-tabulated--compare-remaining)
("Ack" 3 t)
("Description" 0 t)])
(add-hook 'window-configuration-change-hook #'tmr-tabulated--window-hook nil t)
(add-hook 'tabulated-list-revert-hook #'tmr-tabulated--set-entries nil t)
(tmr-tabulated--set-entries)
(tabulated-list-init-header)
(tabulated-list-print))
(defun tmr-tabulated--timer-at-point ()
"Return the timer on the current line or nil."
(and (eq major-mode #'tmr-tabulated-mode) (tabulated-list-get-id)))
(defun tmr-tabulated--refresh ()
"Refresh *tmr-tabulated-view* buffer if it exists."
(when-let (buf (get-buffer "*tmr-tabulated-view*"))
(with-current-buffer buf
(let ((lines (line-number-at-pos)))
(revert-buffer)
(when (and (bobp) (> lines 1))
(forward-line (1- lines))
(unless (tabulated-list-get-id)
(forward-line -1)))))))
(add-hook 'tmr--update-hook #'tmr-tabulated--refresh)
(add-hook 'tmr--read-timer-hook #'tmr-tabulated--timer-at-point)
(make-obsolete 'tmr-tabulated-clone #'tmr-clone "0.4.0")
(make-obsolete 'tmr-tabulated-edit-description #'tmr-edit-description "0.4.0")
(make-obsolete 'tmr-tabulated-reschedule #'tmr-reschedule "0.4.0")
(provide 'tmr-tabulated)
;;; tmr-tabulated.el ends here