Setting limit via API

[Brain-Kiel]

Hi everybody,
I'm trying to set the inverter limit with another ESP32 using HTTPClient class.
Reading works fine but I'm struggling while setting the inverter limit.
Testing the given cUrl command works fine:

~$ curl -u "admin:password" http://192.168.10.10/api/limit/config -d 'data={"serial":"11418180xxxx", "limit_type":1, "limit_value":50}'

but http.get() on ESP32 always gives '-5' (HTTPC_ERROR_CONNECTION_LOST) as respond in the following code - no matter which String is uncommented:

HTTPClient http;

// String dataPart = "'data={\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}'";
// String dataPart = "\"data={\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}\"";
// String dataPart = "data=\"{\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}\"";
// String dataPart = "data='{\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}'";
// String dataPart = "'{\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}'";
// String dataPart = "\"{\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}\"";

// Send request
http.begin("http://admin:[email protected]/api/limit/config");
http.POST(dataPart);

Serial.print("*WM-> HTTP Resonse-Code: ");
Serial.println(http.GET());

// Read response
Serial.print("*WM-> HTTP Resonse-Text: ");
Serial.println(http.getString());

// Disconnect
http.end();

Can anybody set me back on the track?
Thanks.

Edit: URL in http.begin() corrected

[Brain-Kiel]

There was an error in the code snippet above that takes me a step forward:

String dataPart = "{\"serial\":\"1141xxxxxxxx\", \"limit_type\":1, \"limit_value\":50}";

// Send request
http.begin("http://admin:[email protected]/api/limit/config");
int httpResonseCode= http.POST(dataPart);

Serial.print("*WM-> HTTP Resonse-Code: ");
Serial.println(httpResonseCode);

// Read response
Serial.print("*WM-> HTTP Resonse-Text: ");
Serial.println(http.getString());

The http.getString() now reads:

{
    "type": "warning",
    "message": "No values found!",
    "code": 1002
}

[Startertrek]

in Python this works:
headers = {'Content-Type': 'application/x-www-form-urlencoded'}
payload = f'''data={{"serial":"{self.serialNumber}", "limit_type":1, "limit_value":{newLimit}}}'''
newLimit = requests.post(url=f'{self.URI_PostLimitSet}', data=payload, auth=('', ''), headers=headers)

[Brain-Kiel]

my final solution for the ESP32 is:

    const char* URL_LIMIT = "http://192.168.XXX.XXX/api/limit/config";

    const uint16_t limitType_ANP = 0;	// AbsoluteNonPersistent
    const uint16_t limitType_RNP = 1;	// RelativeNonPersistent
    const uint16_t limitType_AP = 256;	// AbsolutePersistent
    const uint16_t limitType_RP = 257;	// RelativePersistent
    
    char MSG_POST[80];
    sprintf(MSG_POST, "data={'serial':'%s','limit_type':%i,'limit_value':%i}", "1141XXXXXXXX", limitType_RNP, 50);

    Serial.print(F("*WM-> HTTP Request-Code: "));
    Serial.println(MSG_POST);

    HTTPClient http;

    http.begin(URL_LIMIT);
    http.addHeader(F("Content-Type"), F("application/x-www-form-urlencoded"));
    http.setAuthorization(openDTU_USER, openDTU_PASS);

    int httpResonseCode = http.POST(MSG_POST);
    String httpResponseStr = http.getString();

    Serial.print(F("*WM-> HTTP Resonse-Code: "));
    Serial.println(httpResonseCode);
    Serial.print(F("*WM-> HTTP Resonse-Text: "));
    Serial.println(httpResponseStr);

headers / .addHeader() was the missing link...

[Gerdzipl]

Thanks for that code, it is running well.....but: The Response on my monitor looks like this:

*WM-> HTTP Request-Code: data={'serial':'112xxxxxxxx','limit_type':1,'limit_value':50}
*WM-> HTTP Resonse-Code: 200
WM-> HTTP Resonse-Text: �����mR=O�0�ݑ����.$��!�Ba`i%Z!F7�&n�۲�D��>��b��>�{>g�����{��ultq���;ha���at���(�t�s�Q@Y��0�l�{O^��.......
...and so on
Is there any idea about the cause of this problem?

I would be great to get a solution!

[Borchi013]

I had same problem by using curl. Got warning: {"type":"warning","message":"No values found!","code":1002}.
Here an Arduino sketch for setting power limit via REST API and e.g. ESP8266. Response should be: {"type":"success","message":"Settings saved!","code":1001}

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>

const char* ssid = "WLAN";
const char* password = "xxxxxxxx";
int Limit = 10; //test value only

void setup() {
Serial.begin(115200);
WiFi.begin(ssid, password);

while (WiFi.status() != WL_CONNECTED) {
delay(1000);
Serial.println("Verbindung zum WiFi wird hergestellt...");
}
Serial.println("WiFi verbunden");

HTTPClient http;
http.begin("http://opendtu-123456/api/limit/config");
http.setAuthorization("admin", "openDTU42");
http.addHeader("Content-Type", "application/x-www-form-urlencoded");

String payload = "data={"serial":"11218381xxxx", "limit_type":1, "limit_value":" + String(Limit) + "}";
int httpResponseCode = http.POST(payload);

Serial.println(payload); // for test purposes only

if (httpResponseCode > 0) {
String response = http.getString();
Serial.println(httpResponseCode);
Serial.println(response);
} else {
Serial.println("Fehler bei der HTTP-Anfrage");
}

http.end();
}

void loop() {
// Nichts in der loop-Funktion
}