Simplify Test Case Discarding

[moodmosaic]

As part of the great work in #38, we introduced a way to discard test cases using helper functions like:

(define-read-only (can-test-protocol-burn-balance-decrease (address principal) (amount uint))
  (and
    (is-eq tx-sender deployer)
    (not (is-eq amount u0))
    (not (> amount (unwrap-panic (get-balance-available address))))
  )
)

(define-public (test-protocol-burn-balance-decrease (address principal) (amount uint))
  (let (
      (initial-balance (unwrap-panic (get-balance-available address)))
    )
    (ok
      (begin
        (try! (protocol-burn amount address))
        (asserts!
          (is-eq
            (unwrap-panic (get-balance-available address))
            (- initial-balance amount))
          ERR_FAILED_ASSERTION)
        true))))

While functional, this approach doesn't scale well for larger codebases:

• The number of discard functions can grow significantly.
• Maintenance becomes tricky—e.g., changing a function signature requires updates in multiple places.

---

Instead of using discard functions, we could simplify by signaling discards at the type level:

• ok(true): Test passes.
• ok(false): Test is discarded.
• Errors or panics: Test fails.

(define-public (test-protocol-burn-balance-decrease (address principal) (amount uint))
  (let (
      (initial-balance (unwrap-panic (get-balance-available address)))
    )
    (ok
      (if
        (or
          (not (is-eq tx-sender deployer))
          (is-eq amount u0)
          (> amount initial-balance))
        false ;; Test is discarded.
        (begin
          (try! (protocol-burn amount address))
          (asserts!
            (is-eq
              (unwrap-panic (get-balance-available address))
              (- initial-balance amount))
            ERR_FAILED_ASSERTION) ;; Test fails.
          true))))) ;; Test passes.

This eliminates the need for separate discard functions, reducing boilerplate and improving maintainability.