Note to F# users: A lot of the extension methods are not usable due to a compiler issue

[bddckr]

Spectre.Console uses extension methods to offer a fluent API. Because the extension methods use the same names that the properties use, F# users run into this compiler issue: dotnet/fsharp#11580.

As listed in the linked issue, there is no way to currently call the affected extension methods from F#. As a workaround one can call the extension method as a regular method, though that is quite unergonomic. Personally I've resorted to only utilize the properties for now.

[kurt-mueller-osumc]

This just bit me! I just tried to convert this simple example into F#:

open System

open Spectre.Console.Cli

type AddSettings() =
    inherit CommandSettings()

    [<CommandArgument(0, "[PROJECT]")>]
    member val Project = "" with get, set

type AddPackageSettings() =
    inherit AddSettings()

    [<CommandArgument(0, "<PACKAGE_NAME>")>]
    member val PackageName = "" with get, set

    [<CommandOption("-v|--version <VERSION>")>]
    member val Version = "" with get, set

 type AddReferenceSettings() =
    inherit AddSettings()

    [<CommandArgument(0, "<PROJECT_REFERENCE>")>]
    member val ProjectReference = "" with get, set

type AddPackageCommand() =
    inherit Command<AddPackageSettings>()

    override _.Execute (context,  settings) = 0

type AddReferenceCommand() =
    inherit Command<AddReferenceSettings>()

    override _.Execute(context, settings) = 0


// Define a function to construct a message to print
let from whom =
    sprintf "from %s" whom

[<EntryPoint>]
let main argv =
    let message = from "F#" // Call the function
    let app = CommandApp()

    app.Configure(fun config ->
        config.AddBranch<AddSettings>("add", fun add ->
            add.AddCommand<AddPackageCommand>("package")
            add.AddCommand<AddReferenceCommand>("reference")
        )
    )

    app.Run(argv)

Unfortunately, I keep running into this error:

[kurt-mueller-osumc]

If anybody wants internet points, I posted this as a StackOverflow question: https://stackoverflow.com/questions/69363591/converting-spectre-consoles-introduction-example-to-f

[bddckr]

@kurt-mueller-osumc Here's how I solved that issue:

1. Explicitly add interface ICommandLimiter<AddSettings> to the Command subclasses that use inheritance in the settings from AddSettings.
2. Change the AddBranch call to infer the generic argument by only annotating the IConfigurator's type: config.AddBranch("add", fun (add: IConfigurator<AddSettings>) -> ....

open System

open Spectre.Console.Cli

type AddSettings() =
    inherit CommandSettings()

    [<CommandArgument(0, "[PROJECT]")>]
    member val Project = "" with get, set

type AddPackageSettings() =
    inherit AddSettings()

    [<CommandArgument(0, "<PACKAGE_NAME>")>]
    member val PackageName = "" with get, set

    [<CommandOption("-v|--version <VERSION>")>]
    member val Version = "" with get, set

 type AddReferenceSettings() =
    inherit AddSettings()

    [<CommandArgument(0, "<PROJECT_REFERENCE>")>]
    member val ProjectReference = "" with get, set

type AddPackageCommand() =
    inherit Command<AddPackageSettings>()

    interface ICommandLimiter<AddSettings>

    override _.Execute (context,  settings) = 0

type AddReferenceCommand() =
    inherit Command<AddReferenceSettings>()

    interface ICommandLimiter<AddSettings>

    override _.Execute(context, settings) = 0


// Define a function to construct a message to print
let from whom =
    sprintf "from %s" whom

[<EntryPoint>]
let main argv =
    let message = from "F#" // Call the function
    let app = CommandApp()

    app.Configure(fun config ->
        config.AddBranch("add", fun (add: IConfigurator<AddSettings>) ->
            add.AddCommand<AddPackageCommand>("package") |> ignore
            add.AddCommand<AddReferenceCommand>("reference") |> ignore
        )
    )

    app.Run(argv)

(Also posted on SO for visibility 😄)

[kurt-mueller-osumc]

My man! You are awesome. Thank you so much for this. 😃

[patriksvensson]

I'm not very good at F#, but maybe @JamesRandall have some valuable input about this.

[JamesRandall]

@bddckr caught me mid-typing.... awesome answer thank you!

I've not looked at the CLI part of the F# bindings yet and never used them myself but would love suggestions from those of who have used it on what an idiomatic / pleasant approach might be. That feels a bit off topic here though so I've created a thread:

#559

[kurt-mueller-osumc]

Thank you both for your time and brainpower. I really appreciate it.