build.gradle

plugins {
    id 'java'
    id 'application'
    id 'idea'
}

repositories {
    mavenCentral()
}

group 'com.github.silvanheller.mensabot'
version '1.2.0'

def mainClassName = 'com.github.silvanheller.mensabot.main.Main'

compileJava.options.encoding = 'UTF-8'
sourceCompatibility = JavaVersion.VERSION_11

dependencies {

    ////// LOGGING
    implementation 'org.apache.logging.log4j:log4j-api:2.+'
    implementation 'org.apache.logging.log4j:log4j-core:2.+'

    // JSON
    implementation group: 'com.google.code.gson', name: 'gson', version: '2.8.9'

    // API Requests
    implementation group: 'com.squareup.okhttp3', name: 'okhttp', version: '4.9.3'
    implementation group: 'com.microsoft.bing', name: 'bing-imagesearch', version: '1.0.0'

    ////// TELEGRAM
    implementation group: 'org.telegram', name: 'telegrambots', version: '5.+'

    // CONFIG
    implementation group: 'com.typesafe', name: 'config', version: '1.+'

    // SCRAPING
    implementation group: 'org.jsoup', name: 'jsoup', version: '1.+'
}

/*
The following block adds both compile and runtime dependencies to the jar
 */
jar {
    manifest {
        attributes(
                "Manifest-Version": "1.0",
                'Main-Class': mainClassName,
                'multi-release': true
        )
    }
    from {
        configurations.compileClasspath.collect { it.isDirectory() ? it : zipTree(it) }
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    archiveBaseName.set("mensa-bot")

    exclude("META-INF/*.RSA", "META-INF/*.DSA", "META-INF/*.SF")
}

rootProject.tasks.named("jar") {
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}


//IDEA if gradle is buggy
idea {
    module {
        downloadJavadoc = true
        //Exclude downloaded stuff
        excludeDirs += file('storage')
        excludeDirs += file('logs')
    }
}