build.gradle

buildscript {

    apply from: rootProject.file('dependencies.gradle')

    repositories {
        mavenCentral()
        google()
        maven { url "https://plugins.gradle.org/m2" }
    }
    dependencies {
        classpath dep.androidPlugin
        classpath dep.kotlinCompiler
    }
}

plugins {
    id("io.github.gradle-nexus.publish-plugin") version '1.0.0'
    id("org.jetbrains.dokka") version "1.6.0"
}

allprojects {
    repositories {
        mavenCentral()
        google()
        maven { url "https://plugins.gradle.org/m2" }
    }

    ext.applyForPlugin = { String plugin, Closure<Project> action ->
        applyForPlugins([plugin], action)
    }

    ext.applyForPlugins = { Iterable<String> plugins, Closure<Project> action ->
        for (String plugin : plugins) {
            if (project.plugins.hasPlugin(plugin)) {
                action.call(project)
            } else {
                project.plugins.withId(plugin, {
                    action.call(project)
                })
            }
        }
    }

    tasks.withType(Javadoc).configureEach {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
}

subprojects {
    applyForPlugins(['com.android.library']) { project ->
        project.with {
            android {
                compileSdkVersion rootProject.ext.compileSdkVersion
                buildToolsVersion rootProject.ext.buildToolsVersion

                defaultConfig {
                    minSdkVersion rootProject.ext.minSdkVersion
                    targetSdkVersion rootProject.ext.targetSdkVersion

                    testInstrumentationRunner dep.testInstrumentationRunner

                }
                buildTypes {
                    release {
                        minifyEnabled false
                        proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
                    }
                }

                compileOptions {
                    sourceCompatibility rootProject.ext.sourceCompatibilityVersion
                    targetCompatibility rootProject.ext.targetCompatibilityVersion
                }
            }
        }
    }

    applyForPlugins(['java']) { project ->
        project.with {
            sourceCompatibility = rootProject.ext.sourceCompatibilityVersion
            targetCompatibility = rootProject.ext.targetCompatibilityVersion
        }
    }
}

apply from: rootProject.file('nexus-publish.gradle')

tasks.named("dokkaHtmlMultiModule") {
    outputDirectory.set(file("docs"))
}