forked from ARSBlue/ToolBox-4-Iris
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Json.cls
1390 lines (1262 loc) · 50.1 KB
/
Json.cls
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
Include (arsblue.OS, arsblue.Status, arsblue.JS)
/// This class contains JSON utilities
///
/// ARSBlue ToolBox-4-Iris
/// Copyright © 2019 ARS Blue GmbH
/// http://www.ars-blue.at
Class arsblue.util.Json [ Abstract ]
{
/// Finds the JSON index of the first occurrence of a value.
/// The index may be a number if JSON is an array or a named key if JSON is an object.
/// <ul>
/// <li>json...the JSON object.</li>
/// <li>value...the value to search for in JSON object.</li>
/// <li>index...the index to search from in JSON object (optional).</li>
/// </ul>
/// Returns the index of first occurrence of the value or null if not found!
ClassMethod IndexOf(json As %DynamicAbstractObject = {$$$NULLOREF}, value As %RawString, index As %RawString = {$$$NULLOREF}) As %RawString
{
quit:('$$$TypeOf(json,"%DynamicAbstractObject")) $$$NULLOREF
set found=$$$NO
set key=$$$NULLOREF
set iterator=json.%GetIterator()
while (iterator.%GetNext(.key, .jsonValue))
{
$$$Continue('$$$ISNULL(index) && (key']index))
set type=json.%GetTypeOf(key)
continue:($CASE(type,"null":$$$YES,"unassigned":$$$YES,:$$$NO))
if ($CASE(type,"array":$$$YES,"object":$$$YES,:$$$NO) && $$$TypeOf(value,"%DynamicAbstractObject"))
{
if (..Equals(jsonValue, value))
{
set found=$$$YES
quit
}
}
else
{
if (jsonValue=value)
{
set found=$$$YES
quit
}
}
}
quit $S(found:key,1:$$$NULLOREF)
}
/// Copies all the properties of source to the specified target.
/// NOTE: JSON arrays will be concatinated and condition has no effect!
/// <ul>
/// <li>source...the source JSON object.</li>
/// <li>target...the target JSON object (will be created if missing).</li>
/// <li>condition...the copy condition:<ul>
/// <li>0...copy all source properties, overwriting target properties (default).</li>
/// <li>1...copy only source properties not available in target.</li>
/// <li>2...copy only source properties available in target overwriting target properties.</li>
/// </ul></li>
/// </ul>
/// Returns status OK if successfully copied from source to target JSON object, any other status signals failure!
ClassMethod Copy(source As %DynamicAbstractObject = {$$$NULLOREF}, ByRef target As %DynamicAbstractObject = {$$$NULLOREF}, condition As %Integer = 0) As %Status
{
#dim status as %Status = $$$OK
try
{
quit:('$IsObject(source))
set:('$IsObject(target)) target=$ClassMethod(source.%ClassName(1),"%New")
set sourceType=$CASE(source.%ClassName(1),"%Library.DynamicArray":"array","%Library.DynamicObject":"object",:"wrong source class type "_source.%ClassName(1))
set targetType=$CASE(target.%ClassName(1),"%Library.DynamicArray":"array","%Library.DynamicObject":"object",:"wrong target class type "_target.%ClassName(1))
$$$ThrowIf(sourceType'=targetType,"cannot copy different JSON types ("_sourceType_"<>"_targetType_")")
$$$ThrowIf('$CASE(condition,0:$$$YES,1:$$$YES,2:$$$YES,:$$$NO),"cannot copy with invalid condition "_condition)
set iterator=source.%GetIterator()
while (iterator.%GetNext(.key,.value))
{
if (targetType="object")
{
set sourceTypeOf=source.%GetTypeOf(key)
set targetTypeOf=target.%GetTypeOf(key)
continue:((condition=2) && (targetTypeOf="unassigned"))
if ((sourceTypeOf="array") || (sourceTypeOf="object"))
{
kill newValue
set:(sourceTypeOf=targetTypeOf) newValue=target.%Get(key)
$$$ThrowOnError(..Copy(value,.newValue,condition))
set value=newValue
}
else
{
continue:((condition=1) && (targetTypeOf'="unassigned"))
}
do target.%Set(key,value)
}
else // array
{
if (condition=0)
{
do target.%Set(key,value)
}
else
{
set index=..IndexOf(target,value)
if ($$$ISNULL(index) && (condition=1))
{
do target.%Push(value)
}
elseif ('$$$ISNULL(index) && (condition=2))
{
do target.%Set(index,value)
}
}
}
}
}
catch (exc)
{
set status=exc.AsStatus()
}
set:$$$ISERR(status) json=$$$NULLOREF
quit status
}
/// Check if two JSON objects and all there subobjects are equal.
/// <ul>
/// <li>json1...the 1st JSON object to compare</li>
/// <li>json2...the 2nd JSON object to compare</li>
/// <ul>
/// Returns true if both JSON objects are equal, false otherwise
ClassMethod Equals(json1 As %DynamicAbstractObject = {$$$NULLOREF}, json2 As %DynamicAbstractObject = {$$$NULLOREF}) As %Boolean
{
#define CheckEquals(%expr) set equals=%expr quit:'equals
quit:(json1=json2) $$$YES
set json1IsNull=$$$ISNULL(json1),json2IsNull=$$$ISNULL(json2)
quit:(json1IsNull && json2IsNull) $$$YES
quit:((json1IsNull && 'json2IsNull) || ('json1IsNull && json2IsNull)) $$$NO
quit:('$$$TypeOf(json1,"%DynamicAbstractObject") || '$$$TypeOf(json2,"%DynamicAbstractObject")) $$$NO
quit:(json1.%ClassName(1)'=json2.%ClassName(1)) $$$NO
set equals=$$$YES
kill keys
set iterator=json1.%GetIterator()
while (equals && iterator.%GetNext(.key,.value))
{
set keys(key)=""
$$$CheckEquals(json1.%GetTypeOf(key)=json2.%GetTypeOf(key))
if ($$$TypeOf(value,"%DynamicAbstractObject"))
{
$$$CheckEquals(..Equals(value,json2.%Get(key)))
}
else
{
$$$CheckEquals(value=json2.%Get(key))
}
}
quit:'equals $$$NO
set iterator=json2.%GetIterator()
while (equals && iterator.%GetNext(.key,.value))
{
continue:($D(keys(key))) // already checked
set equals=$$$NO
quit
}
quit $S(equals:$$$YES,1:$$$NO)
}
/// Get the differences between two JSON objects.
/// The returned json contains an array[json1,json2] if the given JSON objects are not comparable.
/// The returned json contains an array/object with the keys of the given objects where only those keys with a difference are available as an array[keyValue1,keyValue2] for the key.
/// <ul>
/// <li>json1...the 1st JSON object to check</li>
/// <li>json2...the 2nd JSON object to check</li>
/// <ul>
/// Returns the JSON object with the differences between the given JSON objects or null if no differences found!
ClassMethod Diff(json1 As %DynamicAbstractObject = {$$$NULLOREF}, json2 As %DynamicAbstractObject = {$$$NULLOREF}) As %DynamicAbstractObject
{
quit:(json1=json2) $$$NULLOREF
set json1IsNull=$$$ISNULL(json1),json2IsNull=$$$ISNULL(json2)
set json1IsJSON=$$$TypeOf(json1,"%DynamicAbstractObject"),json2IsJSON=$$$TypeOf(json2,"%DynamicAbstractObject")
if (json1IsNull && json2IsNull)
{
quit $$$NULLOREF
}
elseif ((json1IsNull && 'json2IsNull) || ('json1IsNull && json2IsNull) || 'json1IsJSON || 'json2IsJSON || (json1.%ClassName(1)'=json2.%ClassName(1)))
{
set json=[]
if (json1IsNull) { do json.%Push("","null") }
elseif (json1IsJSON) { do json.%Push(##class(%DynamicAbstractObject).%FromJSON(json1.%ToJSON())) }
else { do json.%Push(json1) }
if (json2IsNull) { do json.%Push("","null") }
elseif (json2IsJSON) { do json.%Push(##class(%DynamicAbstractObject).%FromJSON(json2.%ToJSON())) }
else { do json.%Push(json2) }
quit json
}
set json=$ClassMethod(json1.%ClassName(1),"%New")
kill keys
set iterator=json1.%GetIterator()
while (iterator.%GetNext(.key,.value1))
{
set keys(key)=""
set value2=json2.%Get(key)
set jsonDiff=$$$NULLOREF
if (json1.%GetTypeOf(key)'=json2.%GetTypeOf(key))
{
set jsonDiff=[]
if ($$$ISNULL(value1)) { do jsonDiff.%Push("","null") }
elseif ($$$TypeOf(value1,"%DynamicAbstractObject")) { do jsonDiff.%Push(##class(%DynamicAbstractObject).%FromJSON(value1.%ToJSON())) }
else { do jsonDiff.%Push(value1) }
if ($$$ISNULL(value2)) { do jsonDiff.%Push("","null") }
elseif ($$$TypeOf(value2,"%DynamicAbstractObject")) { do jsonDiff.%Push(##class(%DynamicAbstractObject).%FromJSON(value2.%ToJSON())) }
else { do jsonDiff.%Push(value2) }
}
elseif ($$$TypeOf(value1,"%DynamicAbstractObject"))
{
set jsonDiff=..Diff(value1,value2)
}
elseif (value1'=value2)
{
set jsonDiff=[]
if ($$$ISNULL(value1)) { do jsonDiff.%Push("","null") }
elseif ($$$TypeOf(value1,"%DynamicAbstractObject")) { do jsonDiff.%Push(##class(%DynamicAbstractObject).%FromJSON(value1.%ToJSON())) }
else { do jsonDiff.%Push(value1) }
if ($$$ISNULL(value2)) { do jsonDiff.%Push("","null") }
elseif ($$$TypeOf(value2,"%DynamicAbstractObject")) { do jsonDiff.%Push(##class(%DynamicAbstractObject).%FromJSON(value2.%ToJSON())) }
else { do jsonDiff.%Push(value2) }
}
do:('$$$ISNULL(jsonDiff)) json.%Set(key,jsonDiff)
}
set iterator=json2.%GetIterator()
while (iterator.%GetNext(.key,.value2))
{
continue:($D(keys(key))) // already checked
set jsonDiff=[]
if ($$$ISNULL(value2)) { do jsonDiff.%Set(1,"","null") }
elseif ($$$TypeOf(value2,"%DynamicAbstractObject")) { do jsonDiff.%Set(1,##class(%DynamicAbstractObject).%FromJSON(value2.%ToJSON())) }
else { do jsonDiff.%Set(1,value2) }
do json.%Set(key,jsonDiff)
}
quit $S(json.%Size()=0:$$$NULLOREF,1:json)
}
/// Get a JSON object from an objects extent.
/// <ul>
/// <li>oid...the object identifier (syntax: $LB([id],classname,[streamlocation])) for which a JSON object shall be returned</li>
/// <li>complete...true if all data from given object classname/id shall be exported, false (default) otherwise</li>
/// <li>ignoreId...true if the GUID/id from given object classname/id shall be ignored, false (default) otherwise</li>
/// <li>data...for internal use only - do not use or change!</li>
/// </ul>
/// Returns status OK if successfully exported JSON object from given object classname/id from extent, any other status signals failure and the JSON object is set to null!
ClassMethod GetJSONFromExtent(oid As %List = {$$$NULLOREF}, ByRef json As %DynamicAbstractObject = {$$$NULLOREF}, complete As %Boolean = {$$$NO}, ignoreId As %Boolean = {$$$NO}, ByRef data) As %Status [ ProcedureBlock = 0 ]
{
// we have to use ProcedureBlock=0 because we want to read data content with @-syntax!
new (oid,json,complete,ignoreId,data)
#dim status as %Status=$$$OK
try
{
set id=$LG(oid,1)
set className=$LG(oid,2)
$$$ThrowIf($$$ISNULL(className)||('$$$comClassDefined(className)),"cannot create JSON from invalid classname "_className)
set classType=$$$comClassKeyGet(className,$$$cCLASSclasstype)
$$$ThrowIf('$CASE(classType,$$$cCLASSCLASSTYPESTREAM:$$$YES,$$$cCLASSCLASSTYPEPERSISTENT:$$$YES,$$$cCLASSCLASSTYPESERIAL:$$$YES,:$$$NO),"cannot create JSON from invalid classtype "_classType)
set json={}.%Set($$$JSONClassName,className)
if (classType=$$$cCLASSCLASSTYPEPERSISTENT)
{
if ('$ClassMethod(className,"%Exists",oid))
{
set json=$$$NULLOREF
quit
}
if ('ignoreId)
{
set:(id'="") json.$$$JSONId=id
set GUID=##class(%Persistent).%GUID(oid)
set:(GUID'="") json.$$$JSONGUID=GUID // GUID disabled objects do not have a GUID
}
quit:('complete)
}
elseif (classType=$$$cCLASSCLASSTYPESTREAM)
{
if ('ignoreId)
{
set:(id'="") json.$$$JSONId=id
}
set location=$LG(oid,3)
set:(location'="") json.$$$JSONStreamLocation=location
quit:('complete)
set object=##class(%Stream.Object).%Open($LB(id,className,location)) // we can use a new instance of stream, because it will be loaded from extent and not shared in memory like persistent objects do!
$$$ThrowOnError(object.Rewind())
set json.$$$JSONStreamSize=+object.Size
set data=[],len=1024
while (len>=0)
{
set content=object.Read(.len,.status) $$$Throw(status) $$$Break(len<0)
do data.%Push($System.Encryption.Base64Encode($ZCVT(content,"O","UTF8")))
}
set json.$$$JSONStreamData=data
quit
}
set storageStrategy=$$$comClassKeyGet(className,$$$cCLASSstoragestrategy)
set dataLocation="data"
kill properties
if (classType=$$$cCLASSCLASSTYPEPERSISTENT)
{
set index=""
while ($$$YES)
{
set index=$$$comClassArrayNext(className,$$$cCLASSindex,index) quit:(index="")
quit:($$$comMemberKeyGet(className,$$$cCLASSindex,index,$$$cINDEXtype)=$$$cINDEXTYPEKEY)
}
$$$ThrowIf(index="","cannot find valid key index for classname "_className)
set indexPosition=""
while ($$$YES)
{
set indexPosition=$$$comSubMemberNext(className,$$$cCLASSindex,index,$$$cINDEXproperty,indexPosition) quit:(indexPosition="")
set propertyName=$$$comSubMemberKeyGet(className,$$$cCLASSindex,index,$$$cINDEXproperty,indexPosition,$$$cINDEXPROPproperty)
set properties(propertyName)=$LB(index,$$$cINDEXTYPEKEY,,indexPosition)
}
set dataLocation=$$$comMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdatalocation)
set dataLocation=$S($E(dataLocation,*)=")":$E(dataLocation,1,*-1)_",",1:dataLocation_"(") // open first id key
if ($E(dataLocation,1,11)="{%%PARENT}(") // search for parent(s)
{
set indexCnt=$$$comMemberKeyGet(className,$$$cCLASSindex,index,$$$cINDEXproperty)
set:('indexCnt) indexCnt=1 // ID key only
set parentId=$P(id,"||",1,*-indexCnt) // parent id
set dataLocation=dataLocation_""""_$REPLACE($P(id,"||",*-(indexCnt-1),*),"||",""",""")_"""" // children id
set parentClassName=className
while ($E(dataLocation,1,11)="{%%PARENT}(")
{
set parentName=""
while ($$$YES)
{
set parentName=$$$comMemberNext(parentClassName,$$$cCLASSproperty,parentName) quit:(parentName="")
quit:($$$comMemberKeyGet(parentClassName,$$$cCLASSproperty,parentName,$$$cPROPcardinality)=$$$cPROPCARDINALITYPARENT)
}
$$$ThrowIf(parentName="","cannot export JSON for invalid parent relationship "_parentClassName)
set parentClassName=$$$comMemberKeyGet(parentClassName,$$$cCLASSproperty,parentName,$$$cPROPtype)
set index=""
while ($$$YES)
{
set index=$$$comClassArrayNext(parentClassName,$$$cCLASSindex,index) quit:(index="")
quit:($$$comMemberKeyGet(parentClassName,$$$cCLASSindex,index,$$$cINDEXtype)=$$$cINDEXTYPEKEY)
}
$$$ThrowIf(index="","cannot find valid key index for parent classname "_parentClassName)
set indexCnt=$$$comMemberKeyGet(parentClassName,$$$cCLASSindex,index,$$$cINDEXproperty)
set:('indexCnt) indexCnt=1 // ID key
set parentLocation=$$$comMemberKeyGet(parentClassName,$$$cCLASSstorage,storageStrategy,$$$cSDEFdatalocation)
set dataLocation=$S($E(parentLocation,*)=")":$E(parentLocation,1,*-1)_",""",1:parentLocation_"(""")_$REPLACE($P(parentId,"||",*-(indexCnt-1),*),"||",""",""")_""","_$E(dataLocation,12,*)
set parentId=$P(parentId,"||",1,*-indexCnt) quit:(parentId="")
}
}
else
{
set dataLocation=dataLocation_""""_$REPLACE(id,"||",""",""")_"""" // id keys
}
}
set dataName=""
while ($$$YES)
{
set dataName=$$$comStorageSubMemberNext(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName) quit:(dataName="")
set dataStructure=$$$comStorageSubMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName,$$$cSDEFDATAstructure)
set dataSubscript=$$$comStorageSubMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName,$$$cSDEFDATAsubscript)
set propertyName=$$$comStorageSubMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName,$$$cSDEFDATAattribute)
if (propertyName'="")
{
set properties(propertyName)=$LB(dataName,dataStructure,dataSubscript)
}
else
{
set dataPosition=""
while ($$$YES)
{
set dataPosition=$$$comStorageSubSubMemberNext(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName,$$$cSDEFDATAvalue,dataPosition) quit:(dataPosition="")
set propertyName=$$$comStorageSubSubMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFdata,dataName,$$$cSDEFDATAvalue,dataPosition,$$$cSDEFDATAattribute)
set:(propertyName'="") properties(propertyName)=$LB(dataName,dataStructure,dataSubscript,dataPosition)
}
}
}
set propertyName=""
while ($$$YES)
{
set propertyName=$$$comMemberNext(className,$$$cCLASSproperty,propertyName) quit:(propertyName="")
set propertyType=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPtype)
set propertyRuntimeType=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPruntimetype)
set propertyRuntimeClassType=$$$comClassKeyGet(propertyRuntimeType,$$$cCLASSclasstype)
set propertyRuntimeCardinality=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPcardinality)
set propertyRuntimeCollection=$S(
$$$TypeOf(propertyRuntimeType,"%Collection.AbstractArray"):$$$cPROPCOLLECTIONARRAY,
$$$TypeOf(propertyRuntimeType,"%Collection.AbstractList"):$$$cPROPCOLLECTIONLIST,
$$$TypeOf(propertyRuntimeType,"%RelationshipObject"):$$$cPROPCOLLECTIONLIST,
1:""
)
set property=$G(properties(propertyName)) continue:((property="")&&($CASE(propertyRuntimeCardinality,$$$cPROPCARDINALITYMANY:$$$NO,$$$cPROPCARDINALITYCHILDREN:$$$NO,:$$$YES)))
set propertyValue=$$$NULLOREF
set dataStructure=$LG(property,2)
set dataSubscript=$LG(property,3)
set dataPosition=$LG(property,4)
if (dataStructure=$$$cINDEXTYPEKEY) // all key index properties
{
set propertyValue=$P(id,"||",dataPosition)
$$$ThrowIf($$$ISNULL(propertyValue),"cannot export JSON for invalid key property "_className_"."_propertyName_"=$LB("_$LISTTOSTRING(property)_")")
}
elseif (dataStructure=$$$cSDEFDATASTRUCTURELISTNODE) // all datatype, persistent and serial
{
set global=dataLocation_$S(dataLocation="data":$S(dataSubscript="":"",1:"("_dataSubscript_")"),1:$S(dataSubscript="":")",1:","_dataSubscript_")"))
set propertyValue=$LG($G(@global),dataPosition)
}
elseif (dataStructure=$$$cSDEFDATASTRUCTURESUBNODE) // all %Collection.AbstractArray
{
set global=dataLocation_$S(dataLocation="data":"(",1:",")_dataSubscript_",key)"
set key=""
while ($$$YES)
{
set key=$O(@global,1,value) quit:(key="")
set propertyValue=propertyValue_$LB($LB(key,value))
}
}
elseif (dataStructure=$$$cSDEFDATASTRUCTURENODE) // all %DynamicAbstractObject
{
set global=dataLocation_$S(dataLocation="data":"(",1:",")_dataSubscript_")"
set propertyValue=##class(%DynamicAbstractObject).%FromJSON(@global)
}
elseif ($CASE(propertyRuntimeCardinality,$$$cPROPCARDINALITYMANY:$$$YES,$$$cPROPCARDINALITYCHILDREN:$$$YES,:$$$NO)) // all %RelationshipObject with cardinality many/children
{
set propertyInverse=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPinverse)
set inverseSQLTableName=$$$comClassKeyGet(propertyType,$$$cCLASSsqlqualifiednameQ)
set inverseSQLFieldName=$$$comMemberKeyGet(propertyType,$$$cCLASSproperty,propertyInverse,$$$cPROPsqlfieldname)
set stmt=##class(%SQL.Statement).%New()
$$$ThrowOnError(stmt.%Prepare("select ID from "_inverseSQLTableName_" where "_inverseSQLFieldName_"=?"))
set result=stmt.%Execute(id)
if (result.%SQLCODE<0) $$$Throw($$$ERROR($$$SQLError,result.%Message))
while (result.%Next(.status))
{
$$$Throw(status)
set propertyValue=propertyValue_$LB($LB(result.%Get("ID"),propertyType))
}
}
else
{
$$$Throw("cannot read unknown data structure "_$LISTTOSTRING(property))
}
set:$$$ISNULL(propertyValue) propertyValue=$$$NULLOREF
set jsonValue=$$$NULLOREF
if ($$$TypeOf(propertyValue,"%DynamicAbstractObject"))
{
set jsonValue=propertyValue
}
elseif ((propertyRuntimeCollection'="")&&($CASE(propertyRuntimeCardinality,"":$$$YES,$$$cPROPCARDINALITYMANY:$$$YES,$$$cPROPCARDINALITYCHILDREN:$$$YES,:$$$NO)))
{
$$$ThrowIf('$LV(propertyValue),"cannot export JSON from invalid "_propertyRuntimeCollection_" "_$LISTTOSTRING(property)_$S(propertyRuntimeCardinality="":"",1:","_propertyRuntimeCardinality))
set elementType=$S($$$comMemberDefined(propertyType,$$$cCLASSparameter,"ELEMENTTYPE"):$$$comMemberKeyGet(propertyType,$$$cCLASSparameter,"ELEMENTTYPE",$$$cPARAMdefault),1:propertyType)
set elementType=$CASE(elementType,"":"%String",:elementType)
set elementClassType=$$$comClassKeyGet(elementType,$$$cCLASSclasstype)
set jsonValue=$S(propertyRuntimeCollection=$$$cPROPCOLLECTIONARRAY:{},1:[])
for key=1:1:$LL(propertyValue)
{
set listData=$LG(propertyValue,key)
if (propertyRuntimeCollection=$$$cPROPCOLLECTIONARRAY)
{
$$$ThrowIf('$LV(listData),"cannot export JSON from invalid "__propertyRuntimeCollection_" data "_$LISTTOSTRING(property)_$S(propertyRuntimeCardinality="":"",1:","_propertyRuntimeCardinality))
set listKey=$LG(listData,1)
set listValue=$LG(listData,2)
}
else
{
set listKey=key
set listValue=listData
}
set jsonListValue=$$$NULLOREF
if ($$$ISNULL(listValue))
{
set jsonListValue=$$$NULLOREF
}
elseif ((elementClassType=$$$cCLASSCLASSTYPEPERSISTENT) || (elementClassType=$$$cCLASSCLASSTYPESTREAM))
{
if ('$$$ISLISTEMPTY(listValue))
{
set elementOid=$S($LV(listValue):$LB($LG(listValue,1),$LG(listValue,2,elementType),$LG(listValue,3)),1:$LB(listValue,elementType))
set:((elementClassType=$$$cCLASSCLASSTYPESTREAM) && ($LG(elementOid,3)="")) $LI(elementOid,3)=$$$comMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFstreamlocation)
$$$ThrowOnError(..GetJSONFromExtent(elementOid,.jsonListValue,complete,ignoreId))
}
}
elseif (elementClassType=$$$cCLASSCLASSTYPESERIAL)
{
if ('$$$ISLISTEMPTY(listValue))
{
set:((propertyRuntimeCollection=$$$cPROPCOLLECTIONLIST) && $LV(listValue)) listValue=$LG(listValue,1)
$$$ThrowOnError(..GetJSONFromExtent($LB("",elementType),.jsonListValue,complete,ignoreId,listValue))
}
}
else
{
if ($$$TypeOf(elementType,"%Status") && $$$ISSTATUS(listValue))
{
set jsonListValue=..GetJSONFromStatus(listValue)
}
elseif ($LV(listValue))
{
set jsonListValue=..GetJSONFromList(listValue)
}
else
{
set:$$$comMemberDefined(className,$$$cCLASSmethod,propertyName_"Normalize") listValue=$ClassMethod(className,propertyName_"Normalize",listValue)
set jsonListValue=$$$GETJSVALUE(listValue)
}
}
if ($$$ISNULL(jsonListValue)) { do jsonValue.%Set($S(propertyRuntimeCollection=$$$cPROPCOLLECTIONLIST:listKey-1,1:listKey),"","null") }
elseif ($$$TypeOf(elementType,"%Boolean")) { do jsonValue.%Set($S(propertyRuntimeCollection=$$$cPROPCOLLECTIONLIST:listKey-1,1:listKey),jsonListValue,"boolean") }
else { do jsonValue.%Set($S(propertyRuntimeCollection=$$$cPROPCOLLECTIONLIST:listKey-1,1:listKey),jsonListValue) }
}
}
elseif ((propertyRuntimeClassType=$$$cCLASSCLASSTYPEPERSISTENT) || (propertyRuntimeClassType=$$$cCLASSCLASSTYPESTREAM))
{
if ('$$$ISLISTEMPTY(propertyValue))
{
set propertyOid=$S($LV(propertyValue):$LB($LG(propertyValue,1),$LG(propertyValue,2,propertyRuntimeType),$LG(propertyValue,3)),1:$LB(propertyValue,propertyRuntimeType))
set:((propertyRuntimeClassType=$$$cCLASSCLASSTYPESTREAM) && ($LG(propertyOid,3)="")) $LI(propertyOid,3)=$$$comMemberKeyGet(className,$$$cCLASSstorage,storageStrategy,$$$cSDEFstreamlocation)
$$$ThrowOnError(..GetJSONFromExtent(propertyOid,.jsonValue,$CASE(propertyRuntimeClassType,$$$cCLASSCLASSTYPESTREAM:$$$YES,:$CASE(propertyRuntimeCardinality,$$$cPROPCARDINALITYONE:$$$NO,$$$cPROPCARDINALITYPARENT:$$$NO,:complete)),ignoreId))
}
}
elseif (propertyRuntimeClassType=$$$cCLASSCLASSTYPESERIAL)
{
if ('$$$ISLISTEMPTY(propertyValue))
{
$$$ThrowOnError(..GetJSONFromExtent($LB("",propertyRuntimeType),.jsonValue,complete,ignoreId,propertyValue))
}
}
else
{
if ($$$TypeOf(propertyRuntimeType,"%Status") && $$$ISSTATUS(propertyValue))
{
set jsonValue=..GetJSONFromStatus(propertyValue)
}
elseif ($LV(propertyValue))
{
set jsonValue=..GetJSONFromList(propertyValue)
}
else
{
set:$$$comMemberDefined(className,$$$cCLASSmethod,propertyName_"Normalize") propertyValue=$ClassMethod(className,propertyName_"Normalize",propertyValue)
set jsonValue=$$$GETJSVALUE(propertyValue)
}
}
if ($$$ISNULL(jsonValue)) { do json.%Set(propertyName,"","null") }
elseif ($$$TypeOf(propertyRuntimeType,"%Boolean")) { do json.%Set(propertyName,jsonValue,"boolean") }
else { do json.%Set(propertyName,jsonValue) }
}
}
catch (exc)
{
set status=exc.AsStatus()
}
set:$$$ISERR(status) json=$$$NULLOREF
quit status
}
/// Get a JSON object from an object.
/// <ul>
/// <li>object...the object for which a JSON object shall be returned</li>
/// <li>json...the JSON object from given object</li>
/// <li>complete...true if all data from given object shall be exported, false (default) otherwise</li>
/// <li>ignodeId...true if the GUID/id from given object shall be ignored, false (default) otherwise</li>
/// <li>allowTransient...true if transient data from given object shall be exported, false (default) otherwise</li>
/// </ul>
/// Returns status OK if successfully exported JSON object from given object, any other status signals failure and the JSON object is set to null!
ClassMethod GetJSONFromObject(object As %RegisteredObject = {$$$NULLOREF}, ByRef json As %DynamicAbstractObject = {$$$NULLOREF}, complete As %Boolean = {$$$NO}, ignoreId As %Boolean = {$$$NO}, allowTransient As %Boolean = {$$$NO}) As %Status
{
#dim status as %Status=$$$OK
try
{
if ($$$ISNULL(object))
{
set json=$$$NULLOREF
quit
}
else
{
$$$ThrowIf('$$$TypeOf(object,"%RegisteredObject"),"cannot create JSON from invalid object")
}
set className=object.%ClassName(1)
set json={}.%Set($$$JSONClassName,className)
set classType=$$$comClassKeyGet(className,$$$cCLASSclasstype)
if (classType=$$$cCLASSCLASSTYPEPERSISTENT)
{
if ('ignoreId)
{
set id=object.%Id()
set:(id'="") json.$$$JSONId=id // un-saved objects do not have an id
set GUID=##class(%Persistent).%GUID(object.%Oid())
set:(GUID'="") json.$$$JSONGUID=GUID // GUID disabled objects do not have a GUID
}
quit:('complete)
}
elseif (classType=$$$cCLASSCLASSTYPESTREAM)
{
if ('ignoreId)
{
set id=object.%Id()
set:(id'="") json.$$$JSONId=""_id // un-saved streams do not have an id
}
set json.$$$JSONStreamLocation=object.%Location
quit:('complete)
$$$ThrowOnError(object.Rewind())
set json.$$$JSONStreamSize=+object.Size
set data=[],len=1024
while (len>=0)
{
set content=object.Read(.len,.status) $$$Throw(status) $$$Break(len<0)
do data.%Push($System.Encryption.Base64Encode($ZCVT(content,"O","UTF8")))
}
set json.$$$JSONStreamData=data
quit
}
set collection="",cardinality=""
if ($$$TypeOf(object,"%Collection.AbstractArray"))
{
set collection=$$$cPROPCOLLECTIONARRAY
set json={}
}
elseif ($$$TypeOf(object,"%Collection.AbstractList"))
{
set collection=$$$cPROPCOLLECTIONLIST
set json=[]
}
elseif ($$$TypeOf(object,"%RelationshipObject"))
{
set collection=$$$cPROPCOLLECTIONLIST // works like a list but in real it's an array
set cardinality=object.Cardinality
set json=[]
}
if (collection="")
{
set propertyName=""
for
{
set propertyName=$$$comMemberNext(className,$$$cCLASSproperty,propertyName) $$$Break(propertyName="")
continue:($E(propertyName,1)="%") // ignore any system property
continue:($$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPprivate)) // do not export private property
continue:($$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPmultidimensional)) // do not export multidimensional property
set propertyType=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPruntimetype)
set propertyClassType=$$$comClassKeyGet(propertyType,$$$cCLASSclasstype)
set propertyCardinality=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPcardinality)
continue:(propertyCardinality=$$$cPROPCARDINALITYPARENT) // we do not export parent relations, because children are subscripts of parents!
continue:('$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPstorable) && (propertyCardinality="") && 'allowTransient) // do not export transient property
set value=$Property(object,propertyName)
if ($$$ISNULL(value))
{
set value=$$$NULLOREF
}
elseif (propertyClassType=$$$cCLASSCLASSTYPEDATATYPE)
{
$$$ThrowIf($IsObject(value),"cannot export object as datatype")
if ($LV(value))
{
set value=..GetJSONFromList(value)
}
elseif ($ClassMethod(propertyType,"%Extends","%Status") && $$$ISSTATUS(value))
{
set value=..GetJSONFromStatus(value)
}
else
{
set value=$$$GETJSVALUE(value)
}
}
else
{
$$$ThrowIf('$IsObject(value),"cannot export datatype as object")
if ('$$$TypeOf(value,"%DynamicAbstractObject"))
{
set jvalue=$$$NULLOREF
$$$ThrowOnError(..GetJSONFromObject(value,.jvalue,$CASE(propertyClassType,$$$cCLASSCLASSTYPESTREAM:$$$YES,:$CASE(propertyCardinality,$$$cPROPCARDINALITYONE:$$$NO,$$$cPROPCARDINALITYPARENT:$$$NO,:complete)),ignoreId,allowTransient))
set value=jvalue
}
}
if ($$$ISNULL(value)) { do json.%Set(propertyName,"","null") }
elseif ($CLASSMETHOD(propertyType,"%Extends","%Boolean")) { do json.%Set(propertyName,value,"boolean") }
else { do json.%Set(propertyName,value) }
}
}
elseif ($CASE(cardinality,"":$$$YES,$$$cPROPCARDINALITYMANY:$$$YES,$$$cPROPCARDINALITYCHILDREN:$$$YES,:$$$NO))
{
set elementType=object.ElementType,elementType=$$$ClassType(elementType)
set elementClassType=$$$comClassKeyGet(elementType,$$$cCLASSclasstype)
set key=""
while ($$$YES)
{
set value=object.GetNext(.key) $$$Break(key="")
if ($$$ISNULL(value))
{
set value=$$$NULLOREF
}
elseif (elementClassType=$$$cCLASSCLASSTYPEDATATYPE)
{
$$$ThrowIf($IsObject(value),"cannot export object as datatype")
if ($LV(value))
{
set value=..GetJSONFromList(value)
}
elseif ($ClassMethod(elementType,"%Extends","%Status") && $$$ISSTATUS(value))
{
set value=..GetJSONFromStatus(value)
}
else
{
set value=$$$GETJSVALUE(value)
}
}
else
{
$$$ThrowIf('$IsObject(value),"cannot export datatype as object")
if ('$$$TypeOf(value,"%DynamicAbstractObject"))
{
set jvalue=$$$NULLOREF
$$$ThrowOnError(..GetJSONFromObject(value,.jvalue,$CASE(elementClassType,$$$cCLASSCLASSTYPESTREAM:$$$YES,:complete),ignoreId,allowTransient))
set value=jvalue
}
}
if ($$$ISNULL(value)) { do json.%Set($S(collection=$$$cPROPCOLLECTIONLIST:key-1,1:key),"","null") }
elseif ($CLASSMETHOD(elementType,"%Extends","%Boolean")) { do json.%Set($S(collection=$$$cPROPCOLLECTIONLIST:key-1,1:key),value,"boolean") }
else { do json.%Set($S(collection=$$$cPROPCOLLECTIONLIST:key-1,1:key),value) }
}
}
}
catch (exc)
{
set status=exc.AsStatus()
}
set:$$$ISERR(status) json=$$$NULLOREF
quit status
}
/// Get an object from an JSON object.
/// <ul>
/// <li>json...the JSON object with class information for which an object shall be returned</li>
/// <li>object...the object from the class information</li>
/// <li>complete...true if all data from given JSON object should be imported, false (default) otherwise</li>
/// <li>ignodeId...true if the GUID/id from given JSON object shall be ignored, false (default) otherwise</li>
/// <li>allowTransient...true if transient data from given JSON object shall be imported, false (default) otherwise</li>
/// </ul>
/// Returns status OK if successfully imported object from JSON object, any other status signals failure and the object is set to null!
ClassMethod GetObjectFromJSON(json As %DynamicAbstractObject = {$$$NULLOREF}, ByRef object As %RegisteredObject = {$$$NULLOREF}, complete As %Boolean = {$$$NO}, ignoreId As %Boolean = {$$$NO}, allowTransient As %Boolean = {$$$NO}) As %Status
{
#dim status as %Status=$$$OK
try
{
if ($$$ISNULL(json))
{
set object=$$$NULLOREF
quit
}
elseif ($$$TypeOf(json,"%DynamicArray"))
{
set className=$S($IsObject(object):object.%ClassName(1),1:"")
$$$ThrowIf('($$$TypeOf(className,"%Collection.AbstractList") || $$$TypeOf(className,"%Library.RelationshipObject")),"cannot import array into unknow list class "_className)
}
elseif ($$$TypeOf(json,"%DynamicObject"))
{
set className=json.$$$JSONClassName
if (className="")
{
set className=$S($IsObject(object):object.%ClassName(1),1:"")
$$$ThrowIf('$$$TypeOf(className,"%Collection.AbstractArray"),"cannot import object into unknown array class "_className)
}
elseif (className=$$$JSONStatusClassName)
{
set object=..GetStatusFromJSON(json)
quit
}
}
else
{
$$$Throw("cannot create object from invalid JSON")
}
set classType=$$$comClassKeyGet(className,$$$cCLASSclasstype)
if (classType=$$$cCLASSCLASSTYPEPERSISTENT)
{
set:('$$$TypeOf(object,className)) object=$$$NULLOREF
if ('ignoreId)
{
set:((json.$$$JSONGUID'="") && ('$IsObject(object) || (json.$$$JSONGUID'=##class(%Persistent).%GUID(object.%Oid())))) object=##class(%Persistent).%Open(##class(%GUID).%GUIDFind(json.$$$JSONGUID))
set:((json.$$$JSONId'="") && ('$IsObject(object) || (json.$$$JSONId'=object.%Id()))) object=$ClassMethod(className,"%OpenId",json.$$$JSONId)
}
set:('$IsObject(object)) object=$ClassMethod(className,"%New")
quit:('complete)
}
elseif (classType=$$$cCLASSCLASSTYPESTREAM)
{
set location=json.$$$JSONStreamLocation,id=""
if ('ignoreId)
{
set id=$S(location="":"",1:json.$$$JSONId)
set:((id'="")&&('$D(@(location_"("_id_")")))) id="" // this id does not exist in storage
}
set oid=$LB(id,className,location)
set:('$$$TypeOf(object,className) || ($LISTTOSTRING(object.%Oid())'=$LISTTOSTRING(oid))) object=##class(%Stream.Object).%Open(oid)
if (complete)
{
$$$ThrowOnError(object.Rewind())
set data=json.$$$JSONStreamData
if ($$$TypeOf(data,"%DynamicArray"))
{
set iterator=data.%GetIterator()
while (iterator.%GetNext(.cnt,.content))
{
do object.Write($ZCVT($System.Encryption.Base64Decode(content),"I","UTF8"))
}
}
set size=+json.$$$JSONStreamSize
$$$ThrowIf((size'=object.Size),"stream import from JSON failed (difference in size: json="_size_", stream="_object.Size_")")
}
quit
}
else
{
$$$InitTypeOf(object,className)
}
set collection="",cardinality=""
if ($$$TypeOf(object,"%Collection.AbstractArray"))
{
$$$ThrowIf('$$$TypeOf(json,"%DynamicObject"),"cannot import array from invalid JSON object")
set collection=$$$cPROPCOLLECTIONARRAY
}
elseif ($$$TypeOf(object,"%Collection.AbstractList"))
{
$$$ThrowIf('$$$TypeOf(json,"%DynamicArray"),"cannot import list from invalid JSON array")
set collection=$$$cPROPCOLLECTIONLIST
}
elseif ($$$TypeOf(object,"%RelationshipObject"))
{
$$$ThrowIf('$$$TypeOf(json,"%DynamicArray"),"cannot import relation from invalid JSON array")
set collection=$$$cPROPCOLLECTIONLIST // works like a list but in real it's an array
set cardinality=object.Cardinality
}
if (collection="")
{
set propertyName=""
for
{
set propertyName=$$$comMemberNext(className,$$$cCLASSproperty,propertyName) $$$Break(propertyName="")
continue:($E(propertyName,1)="%") // ignore any system property
continue:($$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPprivate)) // do not import private property
continue:($$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPmultidimensional)) // do not import multidimensional property
continue:($$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPreadonly)) // do not import read only property
set propertyCardinality=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPcardinality)
continue:('$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPstorable) && (propertyCardinality="") && 'allowTransient) // do not import transient property
set propertyType=$$$comMemberKeyGet(className,$$$cCLASSproperty,propertyName,$$$cPROPruntimetype)
set propertyClassType=$$$comClassKeyGet(propertyType,$$$cCLASSclasstype)
set propertyValue=$Property(object,propertyName)
set propertyCollection=$S('$IsObject(propertyValue):"",$$$TypeOf(propertyValue,"%Collection.AbstractArray"):$$$cPROPCOLLECTIONARRAY,$$$TypeOf(propertyValue,"%Collection.AbstractList"):$$$cPROPCOLLECTIONLIST,$$$TypeOf(propertyValue,"%RelationshipObject"):$$$cPROPCOLLECTIONLIST,1:"")
set value=json.%Get(propertyName)
if ($$$ISNULL(value))
{
set propertyValue=$$$NULLOREF
}
elseif (propertyClassType=$$$cCLASSCLASSTYPEDATATYPE)
{
if ($$$TypeOf(value,"%DynamicArray"))
{
set propertyValue=..GetListFromJSON(value)
}
elseif ($$$TypeOf(value,"%DynamicObject") && (value.$$$JSONClassName=$$$JSONStatusClassName))
{
set propertyValue=..GetStatusFromJSON(value)
}
else
{
$$$ThrowIf($IsObject(value),"cannot import object as datatype")
set propertyValue=$$$GETJSVALUE(value)
set:($$$TypeOf(propertyType,"%Library.PosixTime")) propertyValue=+propertyValue
}
}
else
{
$$$ThrowIf('$IsObject(value),"cannot import datatype as object")
if ($$$TypeOf(propertyType,"%DynamicAbstractObject"))
{
set propertyValue=value
}
else
{
$$$ThrowOnError(..GetObjectFromJSON(value,.propertyValue,$CASE(propertyClassType,$$$cCLASSCLASSTYPESTREAM:$$$YES,:$CASE(propertyCardinality,$$$cPROPCARDINALITYONE:$$$NO,$$$cPROPCARDINALITYPARENT:$$$NO,:complete)),ignoreId,allowTransient))
}
}
set $Property(object,propertyName)=propertyValue
}
}
elseif ($CASE(cardinality,"":$$$YES,$$$cPROPCARDINALITYMANY:$$$YES,$$$cPROPCARDINALITYCHILDREN:$$$YES,:$$$NO))
{
set elementType=object.ElementType,elementType=$$$ClassType(elementType)
set elementClassType=$$$comClassKeyGet(elementType,$$$cCLASSclasstype)
kill elementValues
set key=""
while ($$$YES)
{
set elementValue=object.GetNext(.key) quit:(key="")
continue:('$IsObject(elementValue))
$$$ThrowOnError(..GetJSONFromObject(elementValue,.elementKey))
set elementKey=$S($$$TypeOf(elementKey,"%DynamicObject"):elementKey.$$$JSONClassName_"#"_elementKey.$$$JSONId_"#"_elementKey.$$$JSONGUID,1:"")
set:($TR(elementKey,"#","")'="") elementValues(elementKey)=elementValue
}
$$$ThrowOnError(object.Clear())
set iterator=json.%GetIterator()
while (iterator.%GetNext(.key,.value))
{
continue:($CASE(json.%GetTypeOf(key),"null":$$$YES,"unassigned":$$$YES,:$$$NO)) // ignore all null/unassigned values because we cleared the array/list before iteration!
if ($$$ISNULL(value))
{
set elementValue=$$$NULLOREF
}
elseif (elementClassType=$$$cCLASSCLASSTYPEDATATYPE)
{