Delete object

Author: lpil

src/bucket/delete_object.gleam

@@ -0,0 +1,33 @@
+import bucket.{type BucketError, type Credentials}
+import bucket/internal
+import gleam/http
+import gleam/http/request.{type Request, Request}
+import gleam/http/response.{type Response}
+
+pub type RequestBuilder {
+  RequestBuilder(bucket: String, key: String)
+}
+
+pub fn request(bucket bucket: String, key key: String) -> RequestBuilder {
+  RequestBuilder(bucket:, key:)
+}
+
+pub fn build(builder: RequestBuilder, creds: Credentials) -> Request(BitArray) {
+  let query = []
+  let headers = []
+  internal.request(
+    creds,
+    http.Delete,
+    "/" <> builder.bucket <> "/" <> builder.key,
+    query,
+    headers,
+    <<>>,
+  )
+}
+
+pub fn response(response: Response(BitArray)) -> Result(Nil, BucketError) {
+  case response.status {
+    204 -> Ok(Nil)
+    _ -> internal.s3_error(response)
+  }
+}

test/bucket_test.gleam

@@ -1,6 +1,7 @@
 import bucket.{ErrorObject, S3Error}
 import bucket/create_bucket
 import bucket/delete_bucket
+import bucket/delete_object
 import bucket/delete_objects
 import bucket/get_object
 import bucket/head_bucket
@@ -370,3 +371,32 @@ pub fn get_object_found_test() {
     |> httpc.send_bits
   let assert Ok(get_object.Found(<<"yes":utf8>>)) = get_object.response(res)
 }
+
+pub fn delete_object_test() {
+  helpers.delete_existing_buckets()
+  helpers.create_bucket("bucket")
+  helpers.create_object("bucket", "key", <<"ok":utf8>>)
+
+  helpers.does_object_exist("bucket", "key")
+  |> should.be_true
+
+  let assert Ok(res) =
+    delete_object.request(bucket: "bucket", key: "key")
+    |> delete_object.build(helpers.creds)
+    |> httpc.send_bits
+  let assert Ok(Nil) = delete_object.response(res)
+
+  helpers.does_object_exist("bucket", "key")
+  |> should.be_false
+}
+
+pub fn delete_object_not_found_test() {
+  helpers.delete_existing_buckets()
+  helpers.create_bucket("bucket")
+
+  let assert Ok(res) =
+    delete_object.request(bucket: "bucket", key: "key")
+    |> delete_object.build(helpers.creds)
+    |> httpc.send_bits
+  let assert Ok(Nil) = delete_object.response(res)
+}

test/helpers.gleam

@@ -2,6 +2,7 @@ import bucket
 import bucket/create_bucket
 import bucket/delete_bucket
 import bucket/delete_objects
+import bucket/head_object
 import bucket/list_buckets
 import bucket/list_objects
 import bucket/put_object
@@ -88,3 +89,12 @@ fn delete_bucket(name: String) -> Nil {
     }
   }
 }
+
+pub fn does_object_exist(bucket: String, key: String) -> Bool {
+  let assert Ok(res) =
+    head_object.request(bucket, key)
+    |> head_object.build(creds)
+    |> httpc.send_bits
+  let assert Ok(res) = head_object.response(res)
+  res == head_object.Found
+}