year38-fast.7bh

-- 7 Billion Humans (2215) --
-- 38: Seek and Destroy 3 --

-- INSTRUCTIONS: "Find and shred the smallest data cube in the room."

-- AVAILABLE COMMANDS: step, pickUp, drop, giveTo, takeFrom, nearest,
-- set, if, jump, end, comment

-- SIZE: 62 commands (challenge 22, shortest known 17)
-- BEST AVERAGE RUNTIME: 25 seconds (challenge 33, fastest known 11)


if s != shredder:
	-- Find the smallest cube in the column directly above and bring
	-- it back to the bottom wall.
	mem2 = nearest wall
	step n
	step n
	step n
	mem1 = set s
	if c < mem1:
		mem1 = set c
	endif
	if n < mem1:
		mem1 = set n
	endif
	step n
	step n
	step n
	if s < mem1:
		mem1 = set s
	endif
	if c < mem1:
		mem1 = set c
	endif
	if n < mem1:
		mem1 = set n
	endif
	step n
	step n
	if c < mem1:
		mem1 = set c
	endif
	if n < mem1:
		mem1 = set n
	endif
	pickup mem1
	step mem2
	drop
	step n
else:
	-- Find the smallest cube in the line against the bottom wall.
	mem2 = nearest shredder
	step se
	b:
	if e != datacube:
		jump b
	endif
	step e
	c:
	if e != datacube:
		jump c
	endif
	step e
	d:
	if e != datacube:
		jump d
	endif
	mem1 = set w
	if c < mem1:
		mem1 = set c
	endif
	if e < mem1:
		mem1 = set e
	endif
	step e
	step e
	step e
	if w < mem1:
		mem1 = set w
	endif
	if c < mem1:
		mem1 = set c
	endif
	if e < mem1:
		mem1 = set e
	endif
	step e
	step e
	if c < mem1:
		mem1 = set c
	endif
	if e < mem1:
		mem1 = set e
	endif
	pickup mem1
	giveto mem2
endif


-- vim: set autoindent noexpandtab