settings.gradle

pluginManagement {
	repositories {
		mavenCentral()
		gradlePluginPortal()
		maven { url 'https://repo.spring.io/release' }
		if (version.contains('-')) {
			maven { url 'https://repo.spring.io/milestone' }
		}
		if (version.endsWith('-SNAPSHOT')) {
			maven { url 'https://repo.spring.io/snapshot' }
		}
	}
	plugins {
		id 'com.gradle.develocity' version "$develocityVersion"
		id 'io.spring.ge.conventions' version "$springGeConventionsVersion"
	}
}

plugins {
	id "com.gradle.develocity"
	id "io.spring.ge.conventions"
}

rootProject.name = 'spring-security-kerberos'

include 'spring-security-kerberos-management'
include 'spring-security-kerberos-bom'
include 'spring-security-kerberos-core'
include 'spring-security-kerberos-client'
include 'spring-security-kerberos-web'
include 'spring-security-kerberos-test'
include 'spring-security-kerberos-samples:sec-client-rest-template'
include 'spring-security-kerberos-samples:sec-server-client-auth'
include 'spring-security-kerberos-samples:sec-server-spnego-form-auth'
include 'spring-security-kerberos-samples:sec-server-win-auth'
include 'spring-security-kerberos-docs'

rootProject.children.each { project ->
	project.buildFileName = "${project.name}.gradle"
	if (project.name == 'spring-security-kerberos-samples') {
		project.children.each { sampleProject ->
			sampleProject.buildFileName = "${sampleProject.name}.gradle"
		}
	}
}