dependencies.gradle

/*
 * This file essentially extracts the versions of external dependencies.
 * With its name "dependencies.gradle", it should be detected and processed by Dependabot.
 * See https://docs.github.com/en/code-security/supply-chain-security/keeping-your-dependencies-updated-automatically/configuration-options-for-dependency-updates
 * also https://dev.to/cricketsamya/gradle-with-dependabot-1o47
 *
 * Keeping the extra properties in the root 'build.gradle' file does not work as some
 * properties are required by our pre-compiled plugin before we had a chance to define them
 * (no regular code is allowed before 'buildscript'/'plugins').
 *
 * Since Gradle 7.0 there is a new (better option to centralize dependency versions with a version catalog
 * (see https://docs.gradle.org/current/userguide/platforms.html#sec:sharing-catalogs), but
 * it is not (yet) supported by Dependabot, renovate, etc.
 */

static def isSnapshotRelease(versionString) {
	versionString.endsWith('SNAPSHOT')
}

static def showStandardStreams() {
	def propSSS = System.getProperty("showStandardStreams")
	propSSS == null ? false : propSSS == "true"
}

static def javaTargetVersion() {
	// 1.8 is default, because that's currently jqwik's minimum supported version
	def propJV = System.getProperty("javaTargetVersion")
	propJV = propJV == '8' ? '1.8' : propJV
	propJV = propJV == null ? '1.8' : propJV
	propJV
}

ext {
	junitPlatformVersion = '1.11.4'
	junitJupiterVersion = '5.11.4'
	apiGuardianVersion = '1.1.2'
	opentest4jVersion = '1.3.0'
	archunitVersion = '1.3.0'
	assertJVersion = '3.27.0'
	mockitoVersion = '4.11.0' // Mockito 5+ no longer supports Java 8
	systemLambdaVersion = '1.2.1'
	errorproneVersion = '2.36.0'
	kotlinVersion = '2.0.0'
	kotlinxVersion = '1.10.1'
	kotestVersion = '5.9.1'
	jspecifyVersion = '1.0.0'
	moduleName = 'net.jqwik'
	jqwikVersion = '1.9.3-SNAPSHOT'
	isSnapshotRelease = isSnapshotRelease(jqwikVersion)
	showStandardStreams = showStandardStreams()
	javaTargetVersion = javaTargetVersion()
}