add 2side movmean

Author: kongdd

src/ArrayStats/ArrayStats.jl

@@ -518,6 +518,54 @@
         end
         return m
     end
+
+
+    """
+        movmean(x::AbstractVector{T}, win::Tuple{Int64, Int64}=(1, 1); skip_centre=false) where {T<:Real}
+    
+    Compute the simple moving average of a 1-dimensional array `x` over a window defined by `win`, returning an array of the same size as `x`.
+    
+    # Arguments
+    - `x::AbstractVector{T}`: Input array of type `T`.
+    - `win::Tuple{Int64, Int64}`: Tuple defining the window size to the left and right of each element. Default is `(1, 1)`.
+    - `skip_centre::Bool`: If `true`, the center element is skipped in the average calculation. Default is `false`.
+    
+    # Returns
+    - `Vector`: An array of the same size as `x` containing the moving averages.
+    
+    # Example
+    ```julia
+    x = [1, 2, 3, 4, 5]
+    win = (1, 1)
+    movmean(x, win)  # returns [1.5, 2.0, 3.0, 4.0, 4.5]
+    ```
+    """
+    function movmean(x::AbstractVector{T}, win::Tuple{Int, Int}=(1, 1); 
+        skip_centre=false) where {T<:Real}
+        win_left, win_right = win
+        
+        FT = Base.promote_op(/, T, Int64)
+        z = similar(x, FT)
+        ∑ = ∅ = FT(0)
+        ∑w = ∅w = 0
+
+        @inbounds @simd for i ∈ eachindex(x)
+            ibeg = max(i - win_left, firstindex(x))
+            iend = min(i + win_right, lastindex(x))
+            ∑ = ∅
+            ∑w = ∅w
+            for j = ibeg:iend
+                skip = skip_centre && i==j
+                xᵢ = x[j]
+                notnan = (xᵢ == xᵢ) && !skip
+                ∑ += ifelse(notnan, xᵢ, ∅)
+                ∑w += ifelse(notnan, 1, 0)
+            end
+            z[i] = ∑ / ∑w
+        end
+        z
+    end
+
     function movmean(x::AbstractMatrix{T}, n::Number) where T
         mean_type = Base.promote_op(/, T, Int64)
         m = Array{mean_type}(undef, size(x))

test/testArrayStats.jl

@@ -485,6 +485,12 @@
     # Moving average: 1D
     @test movmean(collect(1:10.),5) == movmean(1:10,5)
     @test movmean(1:10,5) == [2.0, 2.5, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 8.5, 9.0]
+
+    # Moving average: 1D, 2side windows
+    @test movmean(1:10, (1, 1)) == [1.5, 2.0, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 9.0, 9.5]
+    @test movmean(1:10, (1, 1); skip_centre=true) == [2.0, 2.0, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 9.0, 9.0]
+    @test movmean(1:10, (1, 2)) == [2.0, 2.5, 3.5, 4.5, 5.5, 6.5, 7.5, 8.5, 9.0, 9.5]
+
     # Moving average: 2D
     @test movmean(repeat(1:10,1,10),5) == repeat([2.0, 2.5, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 8.5, 9.0],1,10)
     @test movmean(repeat(1:10,1,10)',5) == repeat([2.0, 2.5, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 8.5, 9.0],1,10)'