[delta_q] add jq scripts for reading Haskell JSON output

Author: rkuhn

delta_q/docs/cluster_coeff.jq

@@ -0,0 +1,15 @@
+# attempt to find triangles in the network graph produced by the Haskell simulation of Praos
+
+[.[]|.[0]] as $links |
+range(1000) |
+. as $i |
+[$i,
+  (
+    [$links[]|select(contains([$i]))|.[]|select(. != $i)] | unique |
+    . as $peers |
+    length as $l |
+    # count the number of pairs of peers that are connected
+    reduce range($l) as $j (0; . + (reduce range($j + 1;$l) as $k (0; . + (if ($links[]|contains([[$peers[$j],$peers[$k]]])) then 0 else 1 end)))) |
+    [$l, .]
+  )
+]

delta_q/docs/convert_arrivals.jq

@@ -0,0 +1,26 @@
+def format: . * 10000 | round / 10000 | tostring;
+
+.stable_chain_hashes as $stable |
+.entries[] |
+.created as $t0 | .hash as $hash |
+.arrivals | length as $l |
+select($l == 1000 and ($stable|contains([$hash]))) |
+sort |
+[
+  foreach .[]
+  as $p 
+  (
+    0;
+    .+1;
+    [(($p-$t0)|format), (./$l|format)]
+  )
+] |
+reverse |
+[
+  # keep only the last value for each time
+  foreach .[] as $p ([0]; [$p[0], .[0]]; if .[0] != .[1] then "("+$p[0]+", "+$p[1]+")" else null end) |
+  select(type == "string")
+] |
+reverse
+|
+"CDF[" + join(", ") + "]"

delta_q/docs/latencies.jq

@@ -0,0 +1,26 @@
+# This script reads a JSON file from the Haskell simulation of Praos
+# and extracts the inter-node latencies from the network graph definition.
+
+# usage: jq -srf latencies.jq <json_file>
+
+# half of the latencies are "near" (and thus quick) the other half are "far" (and thus slower)
+[.[]|.[1]] | sort |
+["near", [.[range(0;length/2)]]], ["far", [.[range(length/2;length)]]] |
+.[0] as $name |
+.[1] |
+length as $l | . as $v |
+range(1;10) | . as $mult |
+[
+    foreach $v[] as $i (0;
+        .+1;
+        if .%100==0 or .==$l then [$i*$mult, ./$l] else null end) |
+    select(.)
+] |
+reverse |
+[
+  # keep only the last value for each time
+  foreach .[] as $p ([0]; [$p[0], .[0]]; if .[0] != .[1] then "("+($p[0]|tostring)+", "+($p[1]|tostring)+")" else null end) |
+  select(type == "string")
+] |
+reverse |
+"send" + ($mult|tostring) + $name + " := CDF[" + join(", ") + "]"

delta_q/docs/praos_diffusion.sh

@@ -0,0 +1,25 @@
+#!/bin/bash
+
+# usage: praos_diffusion.sh <json_file>
+
+# Reads a JSON output file from the Haskell simulation of Praos,
+# converts the arrival times of each block into a CDF,
+# and outputs the CDFs in a format suitable for the web app.
+
+# The individual traces are considered as representations of
+# different possible diffusion patterns and are thus combined
+# using the probabilistic choice operator.
+
+jq -rf convert_arrivals.jq < "$1" |
+(
+  while read CDF; do
+    if [ -z "$RET" ]; then
+      RET="$CDF"
+      N=1
+    else
+      RET="$CDF\n1<>$N\n$RET"
+      let N++
+    fi
+  done
+  echo -e "$RET"
+)