app-crypt/certbot-dns-rfc2136: add 2.11.0

Signed-off-by: Thibaud CANALE <[email protected]>

app-crypt/certbot-dns-rfc2136/Manifest

@@ -1 +1,2 @@
 DIST certbot-2.10.0.gh.tar.gz 2322931 BLAKE2B cb84815ec2db2b4b365f2f2bdee1749263b540a1b67f9195280bdb122307337d294beb403bc05b236a94ed0782b0d093e2b8527a65cb69cac949fa627388e8bd SHA512 444981952140376808a9aa475a692df91e60fffc6d45902a3f809bc07311a7d6597ad56e712d3dae234450eb1c735db431182e784bc748511e68bf4f5f2d6cbd
+DIST certbot-2.11.0.gh.tar.gz 2322114 BLAKE2B d266483d1ffc9f9274df3d5e389ed961758e77e9455a7324132bb2bfe4896db663642a98ac7250d35fbbd60d6aef0d6d2a58f98ad17130958dcfcd61283c2479 SHA512 ba47fc98faaf47278c58e107356371c06039f70ad539d2ca1ac39462bb45c7a6c55ed525d8bd8b11cd35cf807f3423e19309022751a492ba19ded79cfbb6d7f4

app-crypt/certbot-dns-rfc2136/certbot-dns-rfc2136-2.11.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+PARENT_PN="${PN%-dns-rfc2136}"
+PARENT_P="${PARENT_PN}-${PV}"
+
+DESCRIPTION="RFC 2136 DNS Authenticator plugin for Certbot (Let’s Encrypt client)"
+HOMEPAGE="
+	https://github.com/certbot/certbot
+	https://letsencrypt.org/
+"
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	EGIT_SUBMODULES=()
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PARENT_P}"
+else
+	SRC_URI="
+		https://github.com/certbot/certbot/archive/v${PV}.tar.gz
+			-> ${PARENT_P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv"
+fi
+
+S="${WORKDIR}/${PARENT_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+BDEPEND="
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=app-crypt/acme-${PV}[${PYTHON_USEDEP}]
+	>=app-crypt/certbot-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+# Same than PATCHES but from repository's root directory,
+# please see function `python_prepare_all` below.
+# Simplier for users IMHO.
+PARENT_PATCHES=(
+)
+
+# Here for patches within "${PN}" subdirectory.
+PATCHES=(
+)
+
+python_prepare_all() {
+	pushd "${WORKDIR}/${PARENT_P}" > /dev/null || die
+	[[ -n "${PARENT_PATCHES[@]}" ]] && eapply "${PARENT_PATCHES[@]}"
+	eapply_user
+	popd > /dev/null || die
+
+	distutils-r1_python_prepare_all
+}