Release builds fail due to missing hermesc bin on Windows

[hsjoberg]

Description

Hi, release builds currently fails due to missing hermesc artifact from hermes-compiler. Only Linux and macOS binaries are shipped.

dir node_modules\hermes-compiler\hermesc\

    Directory: C:\Users\CocoT1\Projects\rn84\node_modules\hermes-compiler\hermesc

Mode                 LastWriteTime         Length Name
----                 -------------         ------ ----
d----          2026-02-12    21:29                linux64-bin
d----          2026-02-12    21:29                osx-bin

Steps to reproduce

1. Create a new app from cli community template npx @react-native-community/cli@latest init rn84
2. cd rn84 && npx react-native run-android --mode release

React Native Version

0.84.0

Affected Platforms

Build - Windows

Output of npx @react-native-community/cli info

npx @react-native-community/cli info
info Fetching system and libraries information...
System:
  OS: Windows 11 10.0.26200
  CPU: "(32) x64 AMD Ryzen 9 7950X3D 16-Core Processor          "
  Memory: 47.73 GB / 95.71 GB
Binaries:
  Node:
    version: 24.8.0
    path: C:\Program Files\nodejs\node.EXE
  Yarn:
    version: 1.22.21
    path: C:\Program Files\nodejs\yarn.CMD
  npm:
    version: 11.6.0
    path: C:\Program Files\nodejs\npm.CMD
  Watchman: Not Found
SDKs:
  Android SDK: Not Found
  Windows SDK:
    AllowDevelopmentWithoutDevLicense: Enabled
    AllowAllTrustedApps: Enabled
    Versions:
      - 10.0.18362.0
      - 10.0.19041.0
      - 10.0.22000.0
      - 10.0.22621.0
IDEs:
  Android Studio: AI-251.26094.121.2513.14007798
  Visual Studio:
    - 17.12.35728.132 (Visual Studio Community 2022)
Languages:
  Java:
    version: 17.0.3
    path: C:\Program Files\ojdkbuild\java-17-openjdk-17.0.3.0.6-1\bin\javac.EXE
  Ruby: Not Found
npmPackages:
  "@react-native-community/cli":
    installed: 20.1.0
    wanted: 20.1.0
  react:
    installed: 19.2.3
    wanted: 19.2.3
  react-native:
    installed: 0.84.0
    wanted: 0.84.0
  react-native-windows: Not Found
npmGlobalPackages:
  "*react-native*": Not Found
Android:
  hermesEnabled: true
  newArchEnabled: true
iOS:
  hermesEnabled: Not found
  newArchEnabled: Not found

Stacktrace or Logs

FAILURE: Build failed with an exception.

* What went wrong:
Execution failed for task ':app:createBundleReleaseJsAndAssets'.
> Couldn't determine Hermesc location. Please set `react.hermesCommand` to the path of the hermesc binary file. node_modules/react-native/sdks/hermesc/%OS-BIN%/hermesc

MANDATORY Reproducer

https://github.com/hsjoberg/rn84

Screenshots and Videos

No response

[nexquery]

I'm experiencing the same problem.

[hsjoberg]

Perhaps this one has to be uncommented by the Hermes team?

https://github.com/facebook/hermes/blob/51948b3860e88286c78b5084f2f01c205706a960/.github/workflows/rn-build-hermes.yml#L60-L62

[DewaldDeJager]

I'm also running into this issue.

As a temporary workaround I've created a wrapper script called hermesc.cmd in the android/ directory that will run the Linux binary in WSL:

@echo off
REM Wrapper script to run the Linux hermesc binary via WSL on Windows.
REM This is needed because hermes-compiler does not ship a Windows binary.

setlocal enabledelayedexpansion

set "SCRIPT_DIR=%~dp0"

REM Resolve hermesc Linux binary path
for /f "usebackq tokens=*" %%i in (`wsl wslpath -u "%SCRIPT_DIR%..\node_modules\hermes-compiler\hermesc\linux64-bin\hermesc"`) do set "HERMESC_PATH=%%i"

REM Build argument list, converting backslashes to forward slashes for WSL
set "ARGS="
:argloop
if "%~1"=="" goto :run
set "ARG=%~1"

REM Replace backslashes with forward slashes so WSL treats them as path separators
set "ARG=!ARG:\=/!"

REM Convert absolute Windows paths (e.g. C:/...) to WSL paths
echo !ARG! | findstr /r "^[A-Za-z]:/" >nul 2>&1
if !errorlevel!==0 (
    REM Convert back to backslash temporarily for wslpath
    set "WINARG=!ARG:/=\!"
    for /f "usebackq tokens=*" %%i in (`wsl wslpath -u "!WINARG!"`) do set "ARG=%%i"
)

if defined ARGS (
    set "ARGS=!ARGS! !ARG!"
) else (
    set "ARGS=!ARG!"
)
shift
goto :argloop

:run
wsl !HERMESC_PATH! !ARGS!
exit /b %errorlevel%

And then in the build.gradle configured it to use this wrapper:

//   Use the WSL wrapper ONLY on Windows because hermes-compiler doesn't ship a Windows binary.
if (org.gradle.internal.os.OperatingSystem.current().isWindows()) {
    hermesCommand = "$rootDir/hermesc.cmd"
}

[nexquery]

I'm also running into this issue.

As a temporary workaround I've created a wrapper script called hermesc.cmd in the android/ directory that will run the Linux binary in WSL:

@echo off
REM Wrapper script to run the Linux hermesc binary via WSL on Windows.
REM This is needed because hermes-compiler does not ship a Windows binary.

setlocal enabledelayedexpansion

set "SCRIPT_DIR=%~dp0"

REM Resolve hermesc Linux binary path
for /f "usebackq tokens=*" %%i in (wsl wslpath -u "%SCRIPT_DIR%..\node_modules\hermes-compiler\hermesc\linux64-bin\hermesc") do set "HERMESC_PATH=%%i"

REM Build argument list, converting backslashes to forward slashes for WSL
set "ARGS="
:argloop
if "%~1"=="" goto :run
set "ARG=%~1"

REM Replace backslashes with forward slashes so WSL treats them as path separators
set "ARG=!ARG:=/!"

REM Convert absolute Windows paths (e.g. C:/...) to WSL paths
echo !ARG! | findstr /r "^[A-Za-z]:/" >nul 2>&1
if !errorlevel!==0 (
REM Convert back to backslash temporarily for wslpath
set "WINARG=!ARG:/=!"
for /f "usebackq tokens=*" %%i in (wsl wslpath -u "!WINARG!") do set "ARG=%%i"
)

if defined ARGS (
set "ARGS=!ARGS! !ARG!"
) else (
set "ARGS=!ARG!"
)
shift
goto :argloop

:run
wsl !HERMESC_PATH! !ARGS!
exit /b %errorlevel%
And then in the build.gradle configured it to use this wrapper:

// Use the WSL wrapper ONLY on Windows because hermes-compiler doesn't ship a Windows binary.
if (org.gradle.internal.os.OperatingSystem.current().isWindows()) {
hermesCommand = "$rootDir/hermesc.cmd"
}

Your solution is excellent.