settings.gradle

rootProject.name = 'paparazzi-root'

include ':libs:layoutlib'
include ':libs:native-macarm'
include ':libs:native-macosx'
include ':libs:native-win'
include ':libs:native-linux'
include ':paparazzi'
include ':paparazzi2'
include ':paparazzi-annotations'
include ':paparazzi-preview-processor'
include ':paparazzi-gradle-plugin'

include ':sample'

enableFeaturePreview('TYPESAFE_PROJECT_ACCESSORS')

includeBuild('build-logic') {
  dependencySubstitution {
    substitute module('app.cash.paparazzi:paparazzi-gradle-plugin') using project(':paparazzi-gradle-plugin')
  }
}

def isIdea = !(System.getProperty("idea.version") ?: "").isEmpty()
if (isIdea) {
  includeTestProjectsIntoIDE()
}

private void includeTestProjectsIntoIDE() {
  // Some of the test projects are intentionally supposed to fail. Don't import these into the main project.
  def brokenProjects = [
    "invalid-application-plugin", // intentionally does not import
    "missing-library-plugin", // intentionally does not import
    "missing-supported-plugins", // intentionally does not import
    "multiplatform-plugin-without-android", // intentionally does not import
  ]

  new File(rootDir, "paparazzi-gradle-plugin/src/test/projects").eachDir {
    def dirName = it.name
    if (!dirName.startsWith(".") && !brokenProjects.contains(dirName)) {
      include ":test-projects:$dirName"
      project(":test-projects:$dirName").projectDir = new File(rootDir, "paparazzi-gradle-plugin/src/test/projects/$dirName")
    }
  }
}