Generate definition from a for loop

[tbruyelle]

Hello cue team,

I would like to generate definitions from a list:

list = [ { name:"def1", args: 1}, {name:"def2", args:2}]

for _,v in list {
    "#\(v.name)": {
        args: v.args
    }
}

result:

"#def1": {
	args: 1
}
"#def2": {
	args: 2
}

The problem is the result is not definitions because the names are quoted, what I would like to have is simply:

#def1: {
	args: 1
}
#def2: {
	args: 2
}

Is this possible ?
Thanks in advance

https://cuelang.org/play/?id=qtGk8xde9Px

[myitcv]

You can't currently declare definitions in this way, but you can make them part of an "outer" definition:

package x

#def: {
	let list = [ {name: "def1", args: 1}, {name: "def2", args: 2}]

	for _, v in list {
		"\(v.name)": {
			args: v.args
		}
	}
}

$ cue eval
#def: {
    def1: {
        args: 1
    }
    def2: {
        args: 2
    }
}

[tbruyelle]

Thanks @myitcv but I definitively need to generate definitions (because it's for the openapi export). I ended up generating the cue file in go.

[myitcv]

That's also an option. But note generating fields as part of definition close makes them definitions if accessed through the containing definition, i.e. #def.def1 is itself closed in exactly the same way as #def.#def1 would be.

[tbruyelle]

Interesting, thanks for the info.

[myitcv]

Apologies, I should have given more context in my answer. The relevant part from the spec is:

Referencing a definition will recursively close it.

For example:

exec cue eval x.cue

-- x.cue --
#A: {
        B: {
                name: string
        }
}

b: #A.B & {
        name: "cueckoo"
        age:  42
}

results in:

> exec cue eval x.cue
[stderr]
b: field not allowed: age:
    ./x.cue:2:5
    ./x.cue:7:4
    ./x.cue:9:2
[exit status 1]

because #A is referenced in #A.B.

[cueckoo]

This discussion has been migrated to cue-lang/cue#937.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.