build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "com.gradle.publish:plugin-publish-plugin:0.10.0"
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.12.0"
        classpath "io.freefair.gradle:maven-plugin:3.0.0-rc.3"
    }
}

apply plugin: "io.codearte.nexus-staging"

nexusStaging {
    stagingProfileId = '7e6204597a774f'
    username = findProperty('ossrhUser')
    password = findProperty('ossrhPass')
}

allprojects {
    repositories {
        jcenter()
    }

    group = "io.freefair.gradle"

    plugins.withId("java") {
        def javaVersion = JavaVersion.current()

        if (javaVersion.isJava11Compatible()) {
            javadoc.options.links "https://docs.oracle.com/en/java/javase/$javaVersion.majorVersion/docs/api/"
        } else {
            javadoc.options.links "https://docs.oracle.com/javase/$javaVersion.majorVersion/docs/api/"
        }
        javadoc.options.links "https://docs.gradle.org/$gradle.gradleVersion/javadoc/"
        javadoc.failOnError = false

        sourceCompatibility = 1.8
        targetCompatibility = 1.8

        plugins.apply "jacoco"

        jacocoTestReport.reports.xml.enabled = true

        dependencies {
            compileOnly 'org.projectlombok:lombok:1.18.4'
            annotationProcessor 'org.projectlombok:lombok:1.18.4'

            testCompileOnly 'org.projectlombok:lombok:1.18.4'
            testAnnotationProcessor 'org.projectlombok:lombok:1.18.4'
        }
    }

    plugins.withId("com.gradle.plugin-publish") {
        pluginBundle {
            website = "https://github.com/freefair/gradle-plugins/tree/${version == 'unspecified' ? 'master' : version}${projectDir.toString() - rootDir.toString()}"
            vcsUrl = 'https://github.com/freefair/gradle-plugins'

            mavenCoordinates {
                groupId = project.group
            }
        }
    }

    plugins.withId("maven-publish") {
        publishing {
            publications.withType(MavenPublication) {
                pom {
                    url = 'https://github.com/freefair/gradle-plugins'
                    name = provider { project.description }
                    description = provider { project.description }
                    inceptionYear = '2016'
                    licenses {
                        license {
                            name = 'MIT'
                            url = 'https://github.com/freefair/gradle-plugins/blob/master/LICENSE'
                        }
                    }
                    organization {
                        name = 'FreeFair'
                        url = 'http://joinfaces.org'
                    }
                    developers {
                        developer {
                            id = 'larsgrefer'
                            name = 'Lars Grefer'
                            email = 'github@larsgrefer.de'
                            timezone = 'Europe/Berlin'
                        }
                        developer {
                            id = 'frisch12'
                            name = 'Dennis Fricke'
                            email = 'dennis.fricke@freefair.io'
                            timezone = 'Europe/Berlin'
                        }
                    }
                    ciManagement {
                        system = 'Travis CI'
                        url = 'https://travis-ci.org/freefair/gradle-plugins/'
                    }
                    issueManagement {
                        system = 'Github'
                        url = 'https://github.com/freefair/gradle-plugins/issues'
                    }
                    scm {
                        connection = 'scm:git:https://github.com/freefair/gradle-plugins.git'
                        developerConnection = 'scm:git:git@github.com:freefair/gradle-plugins.git'
                        url = 'https://github.com/freefair/gradle-plugins/'
                    }
                }
            }
        }
    }
}