Helix highlight queries

[gerblesh]

Not sure if it should live in this repository, but I've modified the highlight queries to work with Helix. The problem is that nvim and helix highlight queries are different enough to where this can't just be merged into the highlights.scm as it would subsequently break highlighting in neovim. I'm leaning towards upstreaming these into helix itself once this grammar is stable rather than having the queries as a separate file inside this repo.

; extends
; Comments
(comment) @comment

; Keys
(property) @variable

; Values
(boolean) @constant.builtin.boolean


[
 (number)
 (adjustment)
] @constant.numeric

[
 "+"
 "="
 (keybind_trigger ">")
] @operator

(":") @punctuation.delimiter

; (color) are hex values
(color "#" @punctuation.special
 (#eq? @punctuation.special "#"))

(path_value "?" @keyword.control.conditional
    (#eq? @keyword.control.conditional "?"))

; `palette`
(palette_index) @variable.member

; `config-file`
(config_file_directive (property) @keyword.import)
(config_file_directive (path_value) @string.special.path)


(action_name) @function.builtin
(action_argument (string) @variable.parameter ) 

[
 (string)
 (color)
] @string

; clear is a special keyword that clear all existing keybind up to that point
((keybind_value) @keyword 
 (#eq? @keyword "clear"))

; `keybind`
(keybind_value) @string.special

; NOTE: The order here matters!
[
 (key_qualifier)
 (keybind_modifier)
] @attribute

[
 (modifier_key)
 (key)
] @constant.builtin

screenshot:

[bezhermoso]

Yeah, the order of precedence between the two would necessitate having separate ones. I wouldn't be against bundling a Helix-optimized highlights.scm file if it makes it easier for the purpose of having something to test with as we work on the grammar.