Using geometrySvg

[dgkorenje]

Setting geometrySvg is throwing error at Svg.cs at: path.GetTightBounds(out var result);
An unhandled exception of type 'System.ExecutionEngineException' occurred in LiveChartsCore.SkiaSharpView.dll
I assume SKPath is being disposed causing this error?
If unique string is set, it works fine. But if I reuse the same string (svg path) it will crash.

edit:
Clearing cache before setting the same string seems to work.
VariableSVGPathGeometry.Cache.Clear()

edit2:
ok this doesn't work. Apparently clearing cache if you have two series it will still crash.

If I don't clear cache, the error is here:

[dgkorenje]

Ok I fixed by creating a new class. My gift for the public.

Note that now you have to supply number 0 to 9 for the shape to .GeometrySvg of the lineseries.

`Imports LiveChartsCore.Drawing
Imports LiveChartsCore.SkiaSharpView.Drawing
Imports LiveChartsCore.SkiaSharpView.Drawing.Geometries
Imports SkiaSharp

Public Class CustomChartPoint
Inherits BoundedDrawnGeometry
Implements IDrawnElement(Of SkiaSharpDrawingContext)
Implements IVariableSvgPath

Private Shared ReadOnly ShapeCache As New Dictionary(Of Byte, SKPath)

Public Property ShapeId As Byte = 0

Public Property SVGPath As String Implements IVariableSvgPath.SVGPath
    Get
        Return ShapeId.ToString()
    End Get
    Set(value As String)
        Dim num As Integer
        If Integer.TryParse(value, num) AndAlso ShapeCache.ContainsKey(CByte(num)) Then
            ShapeId = CByte(num)
        End If
    End Set
End Property

Public Sub New()
    PreloadShapes()
End Sub

Public Sub New(shape As Byte)
    ShapeId = shape
    PreloadShapes()
End Sub

Public Shared PointShapes As New Dictionary(Of Byte, String) From {
    {0, SVGPoints.Circle},
    {1, SVGPoints.Check},
    {2, SVGPoints.Cross},
    {3, SVGPoints.Diamond},
    {4, SVGPoints.Gem},
    {5, SVGPoints.Heart},
    {6, SVGPoints.Pentagon},
    {7, SVGPoints.Pin},
    {8, SVGPoints.Square},
    {9, SVGPoints.Star}
}

Private Shared Sub PreloadShapes()
    If ShapeCache.Count > 0 Then Exit Sub
    For Each kvp In PointShapes
        Dim path = SKPath.ParseSvgPathData(kvp.Value)
        ShapeCache(kvp.Key) = path
    Next
End Sub

Public Sub Draw(context As SkiaSharpDrawingContext) Implements IDrawnElement(Of SkiaSharpDrawingContext).Draw
    If Not ShapeCache.ContainsKey(ShapeId) Then Exit Sub

    Dim paint = context.ActiveSkiaPaint
    Dim canvas = context.Canvas
    Dim path = ShapeCache(ShapeId)

    ' Original path bounds (untransformed)
    Dim bounds = path.TightBounds

    ' LiveCharts scales with the largest dimension and includes StrokeWidth (to avoid clipping)
    Dim stroke As Single = If(paint IsNot Nothing, paint.StrokeWidth, 0F)
    Dim maxDim As Single = Math.Max(bounds.Width, bounds.Height)

    canvas.Save()

    ' IMPORTANT: X,Y are the TOP-LEFT of the geometry rect -> move to rect center first
    canvas.Translate(X + Width / 2.0F, Y + Height / 2.0F)

    ' Uniform scale (like Svg.Draw fitToSize:=False)
    Dim sx As Single = Width / (maxDim + stroke)
    Dim sy As Single = Height / (maxDim + stroke)
    canvas.Scale(sx, sy)

    ' Recenter the original path around its own center
    canvas.Translate(-bounds.MidX, -bounds.MidY)

    ' Now draw
    canvas.DrawPath(path, paint)

    canvas.Restore()
End Sub

End Class

`

[beto-rodriguez]

Seems like a bug, #1943 raised

[dgkorenje]

I made my custom CustomChartPointVisual.
The problem is that geometry is set to default when I add points to series and when those points become visible. For some reason when I add points it calls new() in my customchartpointvisual and geometry is set to default for all points. Colors however remain as they are.
Can you check it out. Did I make the class incorrectly?
Series AS LineSeries(Of ObservablePoint, CustomChartPointVisual)

Imports LiveChartsCore.SkiaSharpView.Drawing
Imports LiveChartsCore.SkiaSharpView.Drawing.Geometries
Imports SkiaSharp

Public Class CustomChartPointVisual
    Inherits BoundedDrawnGeometry
    Implements IDrawnElement(Of SkiaSharpDrawingContext)
    Implements IVariableSvgPath

    Private Shared ReadOnly ShapeCache As New Dictionary(Of SByte, SKPath)

    Public Property ShapeId As SByte = 0

    Public Disabled As Boolean = False
    Public Property SVGPath As String Implements IVariableSvgPath.SVGPath
        Get
            Return ShapeId.ToString()
        End Get
        Set(value As String)
            Dim num As Integer
            If Integer.TryParse(value, num) AndAlso num >= -128 AndAlso num <= 127 Then
                If ShapeCache.ContainsKey(CSByte(num)) Then
                    Disabled = False
                Else
                    Disabled = True
                End If
                ShapeId = CSByte(num)
            Else
                Disabled = True
            End If
        End Set
    End Property

    Public Sub New()
        PreloadShapes()
    End Sub

    Public Sub New(shape As SByte)
        ShapeId = shape
        PreloadShapes()
    End Sub

    Public Shared PointShapes As New Dictionary(Of SByte, String) From {
        {0, SVGPoints.Circle},
        {1, SVGPoints.Check},
        {2, SVGPoints.Cross},
        {3, SVGPoints.Diamond},
        {4, SVGPoints.Gem},
        {5, SVGPoints.Heart},
        {6, SVGPoints.Pentagon},
        {7, SVGPoints.Pin},
        {8, SVGPoints.Square},
        {9, SVGPoints.Star}
    }

    Private Shared Sub PreloadShapes()
        If ShapeCache.Count > 0 Then Exit Sub
        For Each kvp In PointShapes
            Dim path = SKPath.ParseSvgPathData(kvp.Value)
            ShapeCache(kvp.Key) = path
        Next
    End Sub

    Public Sub Draw(context As SkiaSharpDrawingContext) Implements IDrawnElement(Of SkiaSharpDrawingContext).Draw
        If Disabled Then Exit Sub

        Dim paint = context.ActiveSkiaPaint
        Dim canvas = context.Canvas
        Dim path = ShapeCache(ShapeId)

        ' Original path bounds (untransformed)
        Dim bounds = path.TightBounds

        ' LiveCharts scales with the largest dimension and includes StrokeWidth (to avoid clipping)
        Dim stroke As Single = If(paint IsNot Nothing, paint.StrokeWidth, 0F)
        Dim maxDim As Single = Math.Max(bounds.Width, bounds.Height)

        canvas.Save()

        ' IMPORTANT: X,Y are the TOP-LEFT of the geometry rect -> move to rect center first
        canvas.Translate(X + Width / 2.0F, Y + Height / 2.0F)

        ' Uniform scale (like Svg.Draw fitToSize:=False)
        Dim sx As Single = Width / (maxDim + stroke)
        Dim sy As Single = Height / (maxDim + stroke)
        canvas.Scale(sx, sy)

        ' Recenter the original path around its own center
        canvas.Translate(-bounds.MidX, -bounds.MidY)

        ' Now draw
        canvas.DrawPath(path, paint)

        canvas.Restore()
    End Sub

End Class