Add Gradle build configuration. (#153)

* Add Gradle build configuration.

* Explicitly set test script since with two builds Travis can't guess

* Migrate benchmarks

* Add publishing repo

Co-authored-by: William Armiros <[email protected]>

Author: Anuraag Agrawal

.gitignore

@@ -8,3 +8,16 @@
 
 *.iml
 /.idea
+
+.gradle
+**/build/
+!src/**/build/
+
+# Ignore Gradle GUI config
+gradle-app.setting
+
+# Avoid ignoring Gradle wrapper jar file (.jar files are usually ignored)
+!gradle-wrapper.jar
+
+# Cache of project
+.gradletasknamecache

.travis.yml

@@ -13,5 +13,14 @@ jdk:
 install:
   - mvn install -DskipTests -Dgpg.skip -Dmaven.javadoc.skip -B -V
 
+script:
+  - mvn test -B
+  - ./gradlew build
+
 sudo: false
 dist: trusty
+
+cache:
+  directories:
+    - $HOME/.gradle/caches
+    - $HOME/.m2

aws-xray-recorder-sdk-apache-http/build.gradle.kts

@@ -0,0 +1,15 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    api(project(":aws-xray-recorder-sdk-core"))
+
+    api("org.apache.httpcomponents:httpclient:4.5.2")
+
+    testImplementation("junit:junit:4.12")
+    testImplementation("org.mockito:mockito-all:1.10.19")
+}
+
+description = "AWS X-Ray Recorder SDK for Java - Apache HTTP Client Proxy"

aws-xray-recorder-sdk-aws-sdk-core/build.gradle.kts

@@ -0,0 +1,14 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    compileOnly("com.fasterxml.jackson.core:jackson-annotations:2.11.0")
+
+    testImplementation("com.fasterxml.jackson.core:jackson-databind")
+    testImplementation("junit:junit:4.12")
+    testImplementation("org.mockito:mockito-all:1.10.19")
+}
+
+description = "AWS X-Ray Recorder SDK for Java - AWS SDK Core"

aws-xray-recorder-sdk-aws-sdk-instrumentor/build.gradle.kts

@@ -0,0 +1,10 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    compileOnly(project(":aws-xray-recorder-sdk-aws-sdk"))
+}
+
+description = "AWS X-Ray Recorder SDK for Java - AWS SDK Instrumentor"

aws-xray-recorder-sdk-aws-sdk-v2-instrumentor/build.gradle.kts

@@ -0,0 +1,10 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    compileOnly(project(":aws-xray-recorder-sdk-aws-sdk-v2"))
+}
+
+description = "AWS X-Ray Recorder SDK for Java - AWS SDK V2 Instrumentor"

aws-xray-recorder-sdk-aws-sdk-v2/build.gradle.kts

@@ -0,0 +1,20 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    api(project(":aws-xray-recorder-sdk-core"))
+
+    implementation(project(":aws-xray-recorder-sdk-aws-sdk-core"))
+
+    api("software.amazon.awssdk:aws-core:2.2.0")
+
+    testImplementation("junit:junit:4.12")
+    testImplementation("org.mockito:mockito-all:1.10.19")
+    testImplementation("org.skyscreamer:jsonassert:1.3.0")
+    testImplementation("software.amazon.awssdk:dynamodb:2.2.0")
+    testImplementation("software.amazon.awssdk:lambda:2.2.0")
+}
+
+description = "AWS X-Ray Recorder SDK for Java - AWS SDK V2"

aws-xray-recorder-sdk-aws-sdk/build.gradle.kts

@@ -0,0 +1,18 @@
+plugins {
+    `java-library`
+    `maven-publish`
+}
+
+dependencies {
+    api(project(":aws-xray-recorder-sdk-core"))
+
+    implementation(project(":aws-xray-recorder-sdk-aws-sdk-core"))
+
+    api("com.amazonaws:aws-java-sdk:1.11.398")
+
+    testImplementation("junit:junit:4.12")
+    testImplementation("org.mockito:mockito-all:1.10.19")
+    testImplementation("org.skyscreamer:jsonassert:1.3.0")
+}
+
+description = "AWS X-Ray Recorder SDK for Java - AWS SDK Handler"

aws-xray-recorder-sdk-benchmark/build.gradle.kts

@@ -0,0 +1,30 @@
+plugins {
+    id("me.champeau.gradle.jmh") version "0.5.0"
+}
+
+val JMH_VERSION = "1.23"
+
+sourceSets {
+    named("jmh") {
+        java {
+            srcDir("tst/main/java")
+        }
+    }
+}
+
+dependencies {
+    jmh(project(":aws-xray-recorder-sdk-core"))
+
+    jmh("org.openjdk.jmh:jmh-generator-annprocess:${JMH_VERSION}")
+    jmhAnnotationProcessor("org.openjdk.jmh:jmh-generator-annprocess:${JMH_VERSION}")
+
+    add("jmhCompileClasspath", platform(project(":dependencyManagement")))
+    add("jmhRuntimeClasspath", platform(project(":dependencyManagement")))
+}
+
+jmh {
+    fork = 1
+    // Required when also including annotation processor.
+    duplicateClassesStrategy = DuplicatesStrategy.EXCLUDE
+    isZip64 = true
+}

aws-xray-recorder-sdk-bom/build.gradle.kts

@@ -0,0 +1,16 @@
+plugins {
+    `java-platform`
+    `maven-publish`
+}
+
+description = "The AWS X-Ray Recorder SDK for Java - BOM"
+
+dependencies {
+    constraints {
+        rootProject.subprojects {
+            if (name.startsWith("aws-xray-recorder-sdk-") && !name.endsWith("-bom")) {
+                api("${group}:${name}:${version}")
+            }
+        }
+    }
+}