build.gradle

// this part adds in ForgeGradle
buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies { classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT' }
}

apply plugin: "forge"

// stuff specific to my mod
group = 'com.github.abrarsyed'
version = "4.6.3"
archivesBaseName = 'secretroomsmod'

minecraft {
    version = "1.7.2-10.12.1.1061" // grab latest forge
    assetDir = "run/assets"

    // replacing
    replace "@CHANGE_VERSION@", "[4.6,)"
    replace "@MC_VERSION@", project.minecraft.version
    replace "@VERSION@", project.version
    replaceIn "SecretRoomsMod.java"
}

// add some stuff to the version
// spit out the version for debugging sake
logger.lifecycle ""+version
version = "${minecraft.version}-$version.${System.getenv().BUILD_NUMBER}"
logger.lifecycle ""+version

processResources
{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in text files, not binary ones.
    from(sourceSets.main.resources.srcDirs) {
        include '**/*.info'

        // replace version and MCVersion
        // forge version is also accessible via project.minecraftforgeVersion
        // it contains the full minecraft version, including buildNumber
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }

    // copy everything else, thats not text
    from(sourceSets.main.resources.srcDirs) { exclude '**/*.info' }
}

repositories {
     maven { // The repo from which to get waila
         name "Mobius Repo"
         url "http://mobiusstrip.eu/maven"
     }
     maven { // the repo from which to get NEI and stuff
         name 'CB Repo'
         url "http://chickenbones.net/maven/"
     }
}

dependencies {
    // I dont have to specify NEI.. because gradle magic. aka: transitive dependency resolution
    compile "mcp.mobius.waila:Waila:1.5.2a"
    compile 'org.projectlombok:lombok:1.12.6'
}

// because the normal output has been made to be obfuscated
task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
}

// add a source jar
task sourceJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

// add a javadoc jar
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

// some crazy stuff to make sure the chicken stuff is in the mods folder...
// because it wont work otherwise...  because FML doesnt laod coremods from the classpath
task copyChicken(type: Copy, dependsOn: "extractUserDev") {
    from configurations.compile
    include "**/*Chicken*.jar", "**/*NotEnoughItems*.jar"
    exclude "**/CodeChickenLib*" // because CCC downloads it anyways.. -_-
    into file(minecraft.assetDir + "/../mods") // paralell to the assets dir
}
tasks.setupDevWorkspace.dependsOn copyChicken
tasks.setupDecompWorkspace.dependsOn copyChicken

// deployement stuff

configurations { deployerJars }

dependencies { deployerJars "org.apache.maven.wagon:wagon-ssh:2.2" }

artifacts {
    archives sourceJar
    archives deobfJar
    archives javadocJar
}

uploadArchives {
    repositories {
        if (project.hasProperty("filesmaven")) {
            logger.info('Publishing to forge files server')

            mavenDeployer {
                configuration = configurations.deployerJars

                repository(url: project.filesmaven.url) {
                    authentication(userName: project.filesmaven.username, privateKey: project.filesmaven.key)
                }

                pom {
                    groupId = project.group
                    version = project.version
                    artifactId = project.archivesBaseName
                    project {
                        name project.archivesBaseName
                        packaging 'jar'
                        description 'SecretRoomsMod '
                        url 'https://github.com/AbrarSyed/SecretRoomsMod-forge'

                        scm {
                            url 'https://github.com/AbrarSyed/SecretRoomsMod-forge'
                            connection 'scm:git:git://github.com/AbrarSyed/SecretRoomsMod-forge.git'
                            developerConnection 'scm:git:git@github.com:AbrarSyed/SecretRoomsMod-forge.git'
                        }

                        issueManagement {
                            system 'github'
                            url 'https://github.com/AbrarSyed/SecretRoomsMod-forge/issues'
                        }

                        licenses {
                            license {
                                name 'The Eclipse Public Liscence'
                                url 'http://www.eclipse.org/legal/epl-v10.html'
                                distribution 'repo'
                            }
                        }

                        developers {
                            developer {
                                id 'AbrarSyed'
                                name 'AbrarSyed'
                                roles { role 'developer' }
                            }
                            developer {
                                id 'AlexBegt'
                                name 'AlexBegt'
                                roles { role 'contributor' }
                            }
                            developer {
                                id 'CaptainShadows'
                                name 'CaptainShadows'
                                roles { role 'contributor' }
                            }
                        }
                    }
                }
            }
        }
        else
        {
            add project.repositories.mavenLocal()
        }
    }
}