Adding Teleport on red crate

[SOF-Ice]

Hi Vdauphin,

I would like to add a teleport on a second red crate without create a FOB

How can i do this ?

[Vdauphin]

Hello,

[btc_player_side, btc_gear_object_2, "Arsenal 2"] call BIS_fnc_addRespawnPosition

https://community.bistudio.com/wiki/BIS_fnc_addRespawnPosition
Put this in init_server.sqf

Cheers

[SOF-Ice]

[] call compileScript ["core\fnc\city\init.sqf"];

["Initialize"] call BIS_fnc_dynamicGroups;
setTimeMultiplier btc_p_acctime;

["btc_m", -1, objNull, "", false, false] call btc_task_fnc_create;
[["btc_dft", "btc_m"], 0] call btc_task_fnc_create;
[["btc_dty", "btc_m"], 1] call btc_task_fnc_create;

if (btc_db_load && {profileNamespace getVariable [format ["btc_hm_%1_db", worldName], false]}) then {
    if ((profileNamespace getVariable [format ["btc_hm_%1_version", worldName], 1.13]) in [btc_version select 1, 21.1]) then {
        [] call compileScript ["core\fnc\db\load.sqf"];
    } else {
        [] call compileScript ["core\fnc\db\load_old.sqf"];
    };
} else {
    if (btc_hideout_n > 0) then {
        for "_i" from 1 to btc_hideout_n do {[] call btc_hideout_fnc_create;};
    } else {
        [] spawn btc_fnc_final_phase;
    };
    
    [] call btc_cache_fnc_init;

    btc_startDate set [3, btc_p_time];
    setDate btc_startDate;

    {
        _x call btc_veh_fnc_add;
    } forEach (getMissionLayerEntities "btc_vehicles" select 0);
    if (isNil "btc_vehicles") then {btc_vehicles = [];};
};

[] call btc_eh_fnc_server;
[btc_ied_list] call btc_ied_fnc_fired_near;
[] call btc_chem_fnc_checkLoop;
[] call btc_chem_fnc_handleShower;
[] call btc_spect_fnc_checkLoop;
if (btc_p_db_autoRestart > 0) then {
    [{
        [19] remoteExecCall ["btc_fnc_show_hint", [0, -2] select isDedicated];
        [btc_db_fnc_autoRestart, [], 5 * 60] call CBA_fnc_waitAndExecute;
    }, [], btc_p_db_autoRestartTime * 60 * 60 - 5 * 60] call CBA_fnc_waitAndExecute;
};

{
    [_x, 30] call btc_veh_fnc_addRespawn;
    if (_forEachIndex isEqualTo 0) then {
        missionNamespace setVariable ["btc_veh_respawnable_1", _x, true];
    };
} forEach (getMissionLayerEntities "btc_veh_respawnable" select 0);
if (isNil "btc_veh_respawnable") then {btc_veh_respawnable = [];};

if (btc_p_side_mission_cycle > 0) then {
    for "_i" from 1 to btc_p_side_mission_cycle do {
        [true] spawn btc_side_fnc_create;
    };
};

{
    ["btc_tag_remover" + _x, "STR_BTC_HAM_ACTION_REMOVETAG", _x, ["#(rgb,8,8,3)color(0,0,0,0)"], "\a3\Modules_F_Curator\Data\portraitSmoke_ca.paa"] call ace_tagging_fnc_addCustomTag;
} forEach ["ACE_SpraypaintRed"];

if (btc_p_respawn_ticketsAtStart >= 0) then {
    if (btc_p_respawn_ticketsShare) then {
        private _tickets = btc_p_respawn_ticketsAtStart;
        if (btc_p_respawn_ticketsAtStart isEqualTo 0) then {
            _tickets = -1;
        };
        [btc_player_side, _tickets] call BIS_fnc_respawnTickets;
    };
};

[btc_player_side, btc_gear_object_1, "Meteoro"] call BIS_fnc_addRespawnPosition;

[Vdauphin]

You need to enable the simulation of "btc_gear_object_1" to be able to use BI Respawn on this object.

[SOF-Ice]

the btc_gear_object_1 is a copy and paste of btc_gear_object. so there are same parameters

[Vdauphin]

Sure but again:

You need to enable the simulation of "btc_gear_object_1" to be able to use BI Respawn on this object.

[SOF-Ice]

My bad, you true ... thanks for all Vdauphin