build.gradle

plugins {
	id 'fabric-loom' version '1.9-SNAPSHOT'
	id 'maven-publish'
    id 'me.modmuss50.mod-publish-plugin' version '0.6.3'
}

loom {
	accessWidenerPath = file("src/main/resources/proviorigins.accesswidener")
    runs {
        datagen {
            inherit server
            name "Data Generation"
            vmArg "-Dfabric-api.datagen"
            vmArg "-Dfabric-api.datagen.output-dir=${file("src/main/generated")}"
            vmArg "-Dfabric-api.datagen.modid=${modid}"

            runDir "build/datagen"
        }
    }
}
 
sourceSets {
    main {
        resources {
            srcDirs += [
                    'src/main/generated'
            ]
        }
    }
}

archivesBaseName = project.archives_base_name
version = project.mod_version + "+" + project.minecraft_version
group = project.maven_group

repositories {
    mavenLocal()
    mavenCentral()
    exclusiveContent {
        forRepository {
            maven {
                name = "Modrinth"
                url = "https://api.modrinth.com/maven"
            }
        }

        filter {
            includeGroup "maven.modrinth"
        }

    }
    maven {
        url = 'https://maven.cafeteria.dev'
        content {
            includeGroup 'net.adriantodt.fabricmc'
        }
    }
    maven {
        url "https://maven.jamieswhiteshirt.com/libs-release"
        content {
            includeGroup "com.jamieswhiteshirt"
        }
    }
    maven { url "https://maven.quiltmc.org/repository/release" }
    maven { url "https://maven.ladysnake.org/releases" }
    maven { url "https://maven.ladysnake.org/snapshots" }
    maven { url "https://masa.dy.fi/maven" }
    maven { url "https://jitpack.io" }
    maven { url "https://maven.shedaniel.me/" }
    maven { url "https://maven.terraformersmc.com/" }
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modImplementation "io.github.apace100:origins-fabric:${project.origins_version}"
	modCompileOnly "maven.modrinth:lambdynamiclights:${project.dynlights_version}"

    modImplementation "com.github.Provismet:LilyLib:${project.lilylib_version}"
    include "com.github.Provismet:LilyLib:${project.lilylib_version}"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

publishMods {
    file = remapJar.archiveFile
    additionalFiles.from(remapSourcesJar.archiveFile)
    changelog = file("changelog.md").text
    type = STABLE
    modLoaders.add("fabric")
    modLoaders.add("quilt")
    displayName = project.version.toString()
    dryRun = providers.environmentVariable("GITHUB_TOKEN").getOrNull() == null || providers.environmentVariable("MODRINTH_TOKEN").getOrNull() == null || providers.environmentVariable("CURSEFORGE_TOKEN").getOrNull() == null

    github {
        repository = "Provismet/${project.github_repo}"
        accessToken = providers.environmentVariable("GITHUB_TOKEN")
        commitish = "${project.github_branch}"
        tagName = "${project.mod_version}-mc${project.minecraft_version}"
        allowEmptyFiles = true
        displayName = "${project.mod_version} - ${project.minecraft_version}"
    }

    modrinth {
        projectId = project.modrinth_id
        accessToken = providers.environmentVariable("MODRINTH_TOKEN")
        minecraftVersionRange {
            start = project.version_start
            end = project.version_end
        }
        requires("fabric-api")
        requires("origins")
        optional("extrade-origins-addon")
        optional("lambdynamiclights")
        optional("pehkui")
    }

    curseforge {
        projectId = project.curseforge_id
        accessToken = providers.environmentVariable("CURSEFORGE_TOKEN")
        clientRequired = true
        serverRequired = true
        minecraftVersionRange {
            start = project.version_start
            end = project.version_end
        }
        requires("fabric-api")
        requires("origins")
        optional("extrade-origins-addon")
        optional("lambdynamiclights")
        optional("pehkui")
    }
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
            version = project.mod_version + "-mc" + project.minecraft_version
            artifactId = project.archives_base_name
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}