build.gradle

/*
 *  BIP32 library, a Java implementation of BIP32
 *  Copyright (C) 2017-2019 Alan Evans, NovaCrypto
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program.  If not, see <https://www.gnu.org/licenses/>.
 *
 *  Original source: https://github.com/NovaCrypto/BIP32
 *  You can contact the authors via github issues.
 */

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.20.0'
    }
}

plugins {
    id 'com.github.spotbugs' version '1.6.9'
}

group 'io.github.novacrypto'
version '2019.01.27'

apply plugin: 'java'
apply from: 'bintray.gradle'

// Generate a dependency version update report for release
// ./gradlew dependencyUpdates -Drevision=release
// https://github.com/ben-manes/gradle-versions-plugin
apply plugin: 'com.github.ben-manes.versions'

spotbugs {
    toolVersion = '3.1.11'
}

allprojects {
    tasks.withType(com.github.spotbugs.SpotBugsTask) {
        reports {
            xml.enabled = false
            html.enabled = true
        }
    }
}

// To upload a new version
// ./gradlew clean build bintrayUpload -Puser=user -Pkey=APIKEY
bintray {
    user = project.ext.properties.user
    key = project.ext.properties.key
    publications = ['maven']
    pkg {
        repo = 'BIP'
        name = project.name
        userOrg = 'novacrypto'
        licenses = ['GPL-3.0']
        vcsUrl = "https://github.com/NovaCrypto/${project.name}.git"
        version {
            name = project.version
        }
    }
}

repositories {
    maven {
        url 'https://dl.bintray.com/novacrypto/Hashing/'
    }
    maven {
        url 'https://dl.bintray.com/novacrypto/BIP/'
    }
    jcenter()
}

compileJava {
    sourceCompatibility = '1.7'
    targetCompatibility = '1.7'
}

dependencies {
    compile 'com.madgag.spongycastle:core:1.58.0.0@jar'
    compile 'io.github.novacrypto:Hash160:2019.01.27@jar'
    compile 'io.github.novacrypto:SHA256:2019.01.27@jar'
    compile 'io.github.novacrypto:ToRuntime:2019.01.27@jar'
    compile 'io.github.novacrypto:Base58:2019.01.27@jar'
    compile 'io.github.novacrypto:BIP32derivation:2019.01.27@jar'
    testCompile 'org.jmockit:jmockit:1.44'
    testCompile 'junit:junit:4.12'
    testCompile 'com.google.code.gson:gson:2.8.5'
    testCompile 'org.assertj:assertj-core:3.11.1'
    testCompile 'io.github.novacrypto:BIP39:2019.01.27@jar'
}

test {
    jvmArgs "-javaagent:${classpath.find { it.name.contains("jmockit") }.absolutePath}"
}

compileJava.options.encoding = 'UTF-8'
compileTestJava.options.encoding = 'UTF-8'
javadoc.options.encoding = 'UTF-8'