build.gradle

import com.mmodding.gradle.api.EnvironmentTarget

plugins {
	id "com.mmodding.gradle" version "0.0.9"
	id "fabric-loom" version "1.7-SNAPSHOT"
	id "maven-publish"
}

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	exclusiveContent {
		forRepository {
			maven {
				name "Modrinth"
				url "https://api.modrinth.com/maven"
			}
		}
		filter {
			includeGroup "maven.modrinth"
		}
	}
}

fabricApi {
	configureDataGeneration()
}

loom {
	accessWidenerPath = file("src/main/resources/extravaganza.accesswidener")
}

mmodding {
	configureFabricModJson {
		name = "Extravaganza!"
		namespace = "extravaganza"
		license = "Code: PolyForm-Shield-1.0.0\\nAssets: All Rights Reserved"
		description = "Extravaganza! is a mod about adding carnival and festivity goodies, as well as some amusing activities through blocks, entities or items."
		icon = "assets/extravaganza/icon.png"
		addAuthor("MModding Team")
		addContributor("FirstMegaGame4 (Developer)")
		addContributor("Chatoine (Model Artist)")
		addContributor("Aeramisu (Pixel Artist)")
		addContributor("Aethyus (Pixel Artist)")
		addContributor("Neokys (Icon Artist)")
		withContact {
			it.homepage = "https://modrinth.com/mod/extravaganza"
			it.sources = "https://github.com/MModding/extravaganza"
			it.issues = "https://github.com/MModding/extravaganza/issues"
		}
		environment = EnvironmentTarget.ANY
		withEntrypoints {
			it.init("com.mmodding.extravaganza.Extravaganza")
			it.client("com.mmodding.extravaganza.client.ExtravaganzaClient")
			it.custom("fabric-datagen", "com.mmodding.extravaganza.ExtravaganzaDataGenerator")
		}
		addMixin("extravaganza.mixins.json")
		accessWidener = "extravaganza.accesswidener"
		withDependencies {
			it.javaVersion = ">=" + 21
			it.minecraftVersion = "~" + project.minecraft_version
			it.fabricLoaderVersion = ">=" + project.loader_version
			it.fabricApiVersion = "*"
		}
		withSuggestions {
			it.addDependency("ouch", ">=" + project.ouch_version)
		}
		withBreakages {
			it.addDependency("ouch", "<" + project.ouch_version)
		}
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// Ouch!
	if (project.ouch_integration) {
		modCompileOnlyApi "maven.modrinth:ouch:${project.ouch_version}"
	}
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 21
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

jar {
	from("LICENSE.md") {
		rename { "${it}_${project.base.archivesName.get()}"}
	}
}

// configure the maven publication
publishing {
	publications {
		create("mavenJava", MavenPublication) {
			artifactId = project.archives_base_name
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}