build.gradle

apply plugin: 'java'
apply plugin: 'antlr'
apply plugin: 'eclipse'
apply plugin: 'idea'

// Java specific build configurations

version = '1.0'
jar {
    manifest {
        attributes 'Implementation-Title': 'Modulo7',
                   'Implementation-Version': 1.0,
                    'Main-Class': 'com.modulo7.cli.Modulo7CLI'
    }

    // remove the security files (from mail.jar / activation.jar) so that the jar will be executable.
    doFirst {
        from (configurations.runtime.resolve().collect { it.isDirectory() ? it : zipTree(it) }) {
            exclude 'META-INF/MANIFEST.MF'
            exclude 'META-INF/*.SF'
            exclude 'META-INF/*.DSA'
            exclude 'META-INF/*.RSA'
        }
    }
}

test {

    //
    classpath = project.sourceSets.test.runtimeClasspath

    // Setup the audiveris jar location in gradle build
    environment 'AUDIVERIS_JAR_LOCATION', '/usr/bin/audiveris/AudiverisApp/dist'

    // show standard out and standard error of the test JVM(s) on the console
    testLogging.showStandardStreams = true

    // set heap size for the test JVM(s)
    minHeapSize = "128m"
    maxHeapSize = "4096m"

    // listen to events in the test execution lifecycle
    beforeTest { descriptor ->
        logger.lifecycle("Running test: " + descriptor)
    }

    // listen to standard out and standard error of the test JVM(s)
    onOutput { descriptor, event ->
        logger.lifecycle("Test: " + descriptor + " produced standard out/err: " + event.message )
    }

    if (System.getProperty('DEBUG', 'false') == 'true') {
        jvmArgs '-Xdebug',
                '-Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=9009'
    }
}

repositories {
    mavenCentral()
}

dependencies {

	compile group: 'org.apache.lucene', name: 'lucene-analyzers', version: '3.6.2'
    compile group: 'org.apache.lucene', name : 'lucene-queryparser', version: '4.0.0'
    compile group: 'org.apache.lucene', name: 'lucene-analyzers-common', version:'4.1.0'
    compile group: 'org.apache.lucene', name: 'lucene-core', version: '4.1.0'
	compile group: 'org.jsoup', name: 'jsoup', version: '1.7.2'
	compile group: 'org.json', name: 'json', version: '20140107'
    compile group: 'com.googlecode.jen-api', name: 'jen-api', version: '4.x.p'
    compile group: 'org.apache.httpcomponents', name:'httpclient',version: '4.5'
    compile group: 'com.googlecode.jen-api', name: 'jen-api', version: '4.x.p'
    compile group: 'commons-cli', name: 'commons-cli', version: '1.3.1'
    compile group: 'commons-io', name: 'commons-io', version: '2.4'
    compile group: 'log4j', name: 'log4j', version: '1.2.17'
    compile group: 'org.apache.avro', name: 'avro', version: '1.7.7'
    compile group: 'commons-collections', name:'commons-collections', version:'3.0'
    compile group: 'org.apache.commons', name:'commons-lang3', version:'3.1'
    compile group: 'org.apache.lucene', name:'lucene-spellchecker', version:'3.3.0'
    compile group: 'org.apache.commons', name:'commons-math3',  version:'3.0'
    compile group: 'org.hdfgroup', name:'hdf-java', version:'2.6.1'
    compile group: 'org.apache.hadoop', name:'hadoop-core', version:'1.2.1'
    compile group: 'org.apache.avro', name:'avro-mapred', version:'1.7.7'
    compile group: 'com.likethecolor', name:'alchemy', version:'1.1.6'
    compile group: 'javazoom', name:'jlayer', version:'1.0.1'
    compile group: 'xom', name:'xom', version:'1.2.5'
    compile group: 'org.apache.commons', name: 'commons-jcs-core', version:'2.0-beta-1'

    compile files('resources/externalDeps/jfugue-5.0.3.jar')

    runtime files('src/main/config')

    // Test compile artifacts
    testCompile 'junit:junit:4.12'

    // Antlr dependency for grammar parsing
    antlr "org.antlr:antlr4:4.5.1" // use ANTLR version 4
}

generateGrammarSource {
    outputs.upToDateWhen { false }

    doLast {
        copy {
            from 'build/generated-src/antlr/main/'
            include '*.java*'
            into 'src/main/java/com/modulo7/modulo7SQL'
        }
        project.delete fileTree('build/generated-src/antlr/main').include('*.*')
    }
}

uploadArchives {
    repositories {
       flatDir {
           dirs 'repos'
       }
    }
}