for better inferred effects, avoid relying on `copyto!`?

[nsajko]

The copyto! methods for Memory and Array in Base are currently implemented using a ccall to memmove. While this is fast, it results in worse effects than with a naive implementation:

julia> Base.@assume_effects :terminates_locally function copyto_naive!(dst::Union{Memory, Array}, src::Union{Memory, Array})
           for i ∈ 0:(length(dst) - 0x1)
               dst[begin + i] = src[begin + i]
           end
           dst
       end
copyto_naive! (generic function with 1 method)

julia> Base.infer_effects(copyto!, NTuple{2, Vector{Float32}})
(!c,!e,!n,+t,+s,!m,!u,+o,!r)

julia> Base.infer_effects(copyto_naive!, NTuple{2, Vector{Float32}})
(!c,?e,!n,+t,+s,?m,+u,+o,+r)

A separate issue is that the generic copyto! may be doing aliasing checks, which is wasted effort for Collects.jl.

So it might make sense to implement a simplified replacement for copyto!.

[nsajko]

@inbounds makes copyto_naive! quite a bit faster:

Base.@assume_effects :terminates_locally :noub function copyto_naive!(dst::Union{Memory, Array}, src::Union{Memory, Array, Tuple})
    len = length(dst)
    if len != length(src)
        throw(ArgumentError("length mismatch"))
    end
    @inline begin
        for i ∈ 0:(len - 1)
            @inbounds dst[begin + i] = src[begin + i]
        end
    end
    dst
end

Benchmark:

function make_memories(::Type{V}, m, n) where {V}
    [V(undef, m) for _ ∈ 1:n]
end

function workload(copyto!::CopyTo, memories, vec) where {CopyTo}
    foreach(Base.Fix2(copyto!, vec), memories)
end

using BenchmarkTools

@btime workload(copyto!, mems, vec)       setup=(m = 100; n = 1000; mems = make_memories(Memory{Int8}, m, n); vec = rand(Int8, m);) seconds=Inf samples=10000 evals=1
@btime workload(copyto_naive!, mems, vec) setup=(m = 100; n = 1000; mems = make_memories(Memory{Int8}, m, n); vec = rand(Int8, m);) seconds=Inf samples=10000 evals=1

versioninfo()

[nsajko]

Related upstream issue:

• Effects regression in copyto!(::Memory{Int}, ::Memory{Int}, ::Int) JuliaLang/julia#58750