build.gradle

import com.vanniktech.maven.publish.AndroidSingleVariantLibrary
import com.vanniktech.maven.publish.SonatypeHost

buildscript {
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:8.7.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.9.23"

        classpath 'org.jetbrains.dokka:dokka-gradle-plugin:1.9.20'
        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.30.0'
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }

    plugins.withId("com.vanniktech.maven.publish.base") {
        version "1.1"
        group "com.lazygeniouz"

        mavenPublishing {
            signAllPublications()
            pomFromGradleProperties()
            publishToMavenCentral(SonatypeHost.S01, true)
            configure(new AndroidSingleVariantLibrary("release", true, true))
        }
    }
}

tasks.register('clean', Delete) {
    delete rootProject.layout.buildDirectory
}