Brain.jack

/**
 * The Brain module, used to tell dots how to move
 */
class Brain {
    field Array directions;
    field int step;
    static int brainSize;

    function void config(int _brainSize) {
        let brainSize = _brainSize;
    }

    function int getBrainSize() {
        return brainSize;
    }

    constructor Brain new() {
        var int i;
        let step = -1;
        let directions = Array.new(brainSize);
        while (i < brainSize) {
            let directions[i] = AccelerationVectorPair.random();
            let i = i + 1;
        }
        return this;
    }

    constructor Brain newWithDirections(Array _directions) {
        let step = -1;
        let directions = _directions;
        return this;
    }

    method void instantiate() {
        let step = -1;
    }

    method Array getDirections() {
        return directions;
    }

    method void incStep() {
        let step = step + 1;
    }

    method int getStep() {
        return step + 1;
    }

    method int getNextDirection() {
        let step = step + 1;
        return directions[step];
    }
}